mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-27 07:57:27 +00:00
Philip Balister
2e71e6a6e5
The fftw-dev package RDEPENDS on the fftw package, but the package is not
created. Remove the dependency on fftw so that images using fftw-dev will
build.
Signed-off-by: Philip Balister <philip@balister.org>
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
(cherry picked from commit b393e73446)
Signed-off-by: Armin Kuster <akuster808@gmail.com>
75 lines
1.9 KiB
BlitzBasic
75 lines
1.9 KiB
BlitzBasic
DESCRIPTION = "FFTW"
|
|
SECTION = "libs"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552"
|
|
|
|
SRC_URI = "http://www.fftw.org/fftw-${PV}.tar.gz"
|
|
SRC_URI[md5sum] = "2edab8c06b24feeb3b82bbb3ebf3e7b3"
|
|
SRC_URI[sha256sum] = "8f0cde90929bc05587c3368d2f15cd0530a60b8a9912a8e2979a72dbe5af0982"
|
|
|
|
inherit autotools pkgconfig
|
|
|
|
# we had multiple recipes in the past
|
|
PROVIDES = "fftwl fftwf"
|
|
|
|
EXTRA_OECONF = "--disable-fortran --enable-shared --enable-threads"
|
|
|
|
FFTW_NEON = "${@bb.utils.contains('TUNE_FEATURES', 'neon', '--enable-neon', '', d)}"
|
|
FFTW_NEON_class-native = ""
|
|
|
|
do_configure() {
|
|
# configure fftw
|
|
rm -rf ${WORKDIR}/build-fftw
|
|
mkdir -p ${B}
|
|
cd ${B}
|
|
# full (re)configure
|
|
autotools_do_configure
|
|
mv ${B} ${WORKDIR}/build-fftw
|
|
|
|
# configure fftwl
|
|
rm -rf ${WORKDIR}/build-fftwl
|
|
mkdir -p ${B}
|
|
cd ${B}
|
|
# configure only
|
|
oe_runconf --enable-long-double
|
|
mv ${B} ${WORKDIR}/build-fftwl
|
|
|
|
# configure fftwf
|
|
rm -rf ${WORKDIR}/build-fftwf
|
|
mkdir -p ${B}
|
|
cd ${B}
|
|
# configure only
|
|
oe_runconf --enable-single ${FFTW_NEON}
|
|
mv ${B} ${WORKDIR}/build-fftwf
|
|
}
|
|
|
|
do_compile() {
|
|
for lib in fftw fftwl fftwf; do
|
|
cd ${WORKDIR}/build-$lib
|
|
autotools_do_compile
|
|
done
|
|
}
|
|
|
|
do_install() {
|
|
for lib in fftw fftwl fftwf; do
|
|
cd ${WORKDIR}/build-$lib
|
|
autotools_do_install
|
|
done
|
|
}
|
|
|
|
|
|
PACKAGES =+ "libfftw libfftwl libfftwf"
|
|
FILES_libfftw = "${libdir}/libfftw3.so.* ${libdir}/libfftw3_*.so.*"
|
|
FILES_libfftwl = "${libdir}/libfftw3l.so.* ${libdir}/libfftw3l_*.so.*"
|
|
FILES_libfftwf = "${libdir}/libfftw3f.so.* ${libdir}/libfftw3f_*.so.*"
|
|
|
|
PACKAGES =+ "fftw-wisdom fftwl-wisdom fftwf-wisdom fftw-wisdom-to-conf"
|
|
FILES_fftw-wisdom = "${bindir}/fftw-wisdom"
|
|
FILES_fftwl-wisdom = "${bindir}/fftwl-wisdom"
|
|
FILES_fftwf-wisdom = "${bindir}/fftwf-wisdom"
|
|
FILES_fftw-wisdom-to-conf = "${bindir}/fftw-wisdom-to-conf"
|
|
|
|
RDEPENDS_${PN}-dev = ""
|
|
|
|
BBCLASSEXTEND = "native"
|