mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-16 04:17:25 +00:00
Yi Zhao
59e296dc30
The vsomeip stack implements the http://some-ip.com/ (Scalable service-Oriented MiddlewarE over IP (SOME/IP)) protocol. The stack consists out of: a shared library for SOME/IP (libvsomeip3.so) a shared library for SOME/IP's configuration module (libvsomeip3-cfg.so) a shared library for SOME/IP's service discovery (libvsomeip3-sd.so) a shared library for SOME/IP's E2E protection module (libvsomeip3-e2e.so) Signed-off-by: Yi Zhao <yi.zhao@windriver.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
73 lines
2.2 KiB
BlitzBasic
73 lines
2.2 KiB
BlitzBasic
SUMMARY = "The implementation of SOME/IP"
|
|
DESCRIPTION = "The vsomeip stack implements the http://some-ip.com/ \
|
|
(Scalable service-Oriented MiddlewarE over IP (SOME/IP)) protocol."
|
|
HOMEPAGE = "https://github.com/COVESA/vsomeip"
|
|
SECTION = "net"
|
|
|
|
LICENSE = "MPL-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=9741c346eef56131163e13b9db1241b3"
|
|
|
|
SRC_URI = "git://github.com/GENIVI/${BPN}.git;branch=master;protocol=https;name=vsomeip \
|
|
file://0001-Fix-pkgconfig-dir-for-multilib.patch \
|
|
file://0002-Install-example-configuration-files-to-etc-vsomeip.patch \
|
|
file://0003-Do-not-build-external-gtest.patch \
|
|
file://0004-Do-not-specify-PIE-flag-explicitly.patch \
|
|
"
|
|
|
|
SRCREV = "07464840f503670bc75997b8e926b54734ffa410"
|
|
|
|
COMPATIBLE_HOST:mips = "null"
|
|
COMPATIBLE_HOST:mips64 = "null"
|
|
COMPATIBLE_HOST:powerpc = "null"
|
|
COMPATIBLE_HOST:libc-musl = 'null'
|
|
|
|
DEPENDS = "boost dlt-daemon googletest"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit cmake pkgconfig
|
|
|
|
EXTRA_OECMAKE = "-DINSTALL_LIB_DIR:PATH=${baselib} \
|
|
-DINSTALL_CMAKE_DIR:PATH=${baselib}/cmake/vsomeip3 \
|
|
"
|
|
|
|
# For vsomeip-test
|
|
EXTRA_OECMAKE += "-DTEST_IP_MASTER=10.0.3.1 \
|
|
-DTEST_IP_SLAVE=10.0.3.2 \
|
|
-DTEST_IP_SLAVE_SECOND=10.0.3.3 \
|
|
-DTEST_UID=1000 -DTEST_GID=1000 \
|
|
"
|
|
|
|
RDEPENDS:${PN}-test = "bash lsof"
|
|
|
|
do_compile:append() {
|
|
cmake_runcmake_build --target examples
|
|
cmake_runcmake_build --target build_tests
|
|
}
|
|
|
|
do_install:append() {
|
|
install -d ${D}/opt/${PN}-test/examples
|
|
install -m 0755 ${B}/examples/*-sample ${D}/opt/${PN}-test/examples
|
|
install -d ${D}/opt/${PN}-test/examples/routingmanagerd
|
|
install -m 0755 ${B}/examples/routingmanagerd/routingmanagerd \
|
|
${D}/opt/${PN}-test/examples/routingmanagerd
|
|
|
|
install -d ${D}/opt/${PN}-test/test/test/common
|
|
cp -rf ${S}/test/common/examples_policies \
|
|
${D}/opt/${PN}-test/test/test/common/
|
|
|
|
for d in unit_tests network_tests; do
|
|
install -d ${D}/opt/${PN}-test/test/$d
|
|
cp -f ${B}/test/$d/*test* ${D}/opt/${PN}-test/test/$d
|
|
done
|
|
}
|
|
|
|
PACKAGES += "${PN}-test"
|
|
|
|
FILES:${PN}-dbg += " \
|
|
/opt/${PN}-test/.debug/* \
|
|
"
|
|
FILES:${PN}-test = " \
|
|
/opt/${PN}-test \
|
|
"
|