mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-16 04:17:25 +00:00
Wang Mingyu
5f295bc8e9
Changelog: ========== * lib-oauth2: Allow JWT tokens to be validated with missing typ field. + auth: Auth passdb and userdb reply can contain "event_<name>=value" which will be added to login event and mail user event respectively. + lib-master: Set process title during various initialization stages to clearly describe what the process is waiting on. + lib-storage: The mail_temp_scan_interval is now fuzzed incrementing it by 0..30% based on username's hash to reduce the chance of load spikes. + lib-storage: The temp file scan has been moved from the open of the mailbox to the close, to reduce the latency perceived by users. + stats: If metric has fields specified, all these fields are exported as counters to prometheus exposition. - *-login: Processes might have crashed when a SSL connection disconnects uncleanly. - acl: When plugin was loaded \HasChildren and \HasNoChildren flags were calculated incorrectly for mailboxes containing '*' and '%' in their names. - auth: Crash occured if a connection to PostgreSQL database server failed during startup. - auth: Logins with invalid passwords (e.g. unknown scheme) in passdb were failing with "password mismatch" instead of "internal error". - auth: XOAUTH2 and OAUTHBEARER mechanisms were not giving out protocol specific error message on all errors. This especially broke OIDC discovery. - dbox: When last_temp_file_scan header wasn't set (especially after dsync migration), the next mailbox open always triggers the temp file scan. - dict-redis: A crash would occur on transaction rollback. - dsync: Infinite loop causing out of memory would occur when handling mailbox deletion from remote end and hierarchy separators would differ. - dsync: Incremental dsync failed for folder names ending with '%', unless BROKENCHAR was set. Also folder names with '%' elsewhere in them caused each incremental dsync to unnecessarily rename the folder to a temporary name and back. v2.3.19 regression. - imap-hibernate: If an IMAP client unhibernation timed out with "(version received)", the unhibernation could still have successfully finished later on and continued working normally. This was rather confusing, because imap-hibernate already logged that the client got disconnected. - imapc: Crashed when a folder mapped through the virtual plugin disappears from the storage. - imapc: EXPUNGE, EXISTS or FETCH replies from a server for a previously selected mailbox could have been processed as if they belonged to the new mailbox currently being selected. - lib-http: Dovecot HTTP server (doveadm, stats/openmetrics) may have disconnected HTTP clients before the response is fully sent. This happened only on busy servers where kernel's socket buffers were rather full. - lib-http: Fixed a potential crash on http-server if a client disconnected early. v2.3.18 regression. - lib-index: Index file corruption could have caused a crash. Fixes: Panic: file mail-transaction-log-view.c: line 165 (mail_transaction_log_view_set): assertion failed: (min_file_seq <= max_file_seq). - lib-index: Purging an existing >1GB cache file can crash. Now cache files still above 1GB after purging are removed. Fixes: Panic: file mail-index-util.c: line 10 (mail_index_uint32_to_offset): assertion failed: (offset < 0x40000000) - lib-lua: A HTTP client could not resolve DNS names in mail processes, because it expected "the dns-client" socket to exist in the current directory. - lib-oauth2: Dovecot would send client_id and client_secret as POST parameters to the introspection server. These need to be optionally in Basic auth instead. - lib-oauth2: JWT aud validation was not performed if aud was missing from a token, but was configured on Dovecot. - lib-oauth2: JWT key type check was too strict. - lib-oauth2: JWT token audience was not validated against client_id as required by the specification. - lib-ssl-iostream: Using the ssl_require_crl=yes setting may have caused CRL check failures for outgoing SSL/TLS connections, although it was supposed to affect checking CRLs only for client-side SSL certificates. v2.3.17 regression. - lib-sql: MySQL driver leaked memory when connection failed. - lib-storage: Various fixes when running into out of disk space. - master: Service idle_kill setting didn't work properly on busy servers. - mdbox: Temp file scan was done for always empty directories. - mdbox: The fdatasync() call was done in wrong parent directory when writing mails. Also on a failure it crashed instead of logging an error. - notify_status: The plugin crashes if any user initialization fails. - pop3: Sending command with the ':' character caused an assert-crash. v2.3.18 regression. Fixes: Panic: event_reason_code_prefix(): name has ':' - stats: Fix panic when a nonexistent event exporter was referenced while adding a new metric dynamically via doveadm stats add. - stats: If process exported a lot of events and then exited, some of the last events may have become lost. - stats: Invalid Prometheus label names were created with specific histogram group_by configurations. Prometheus rejected these labels. - welcome: The plugin didn't execute in some situations that created INBOX but didn't open it. Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
75 lines
3.4 KiB
BlitzBasic
75 lines
3.4 KiB
BlitzBasic
SUMMARY = "Dovecot is an open source IMAP and POP3 email server"
|
|
HOMEPAGE = "https://www.dovecot.org/"
|
|
DESCRIPTION = "Dovecot is an open source IMAP and POP3 email server for Linux/UNIX-like systems, written with security primarily in mind. Dovecot is an excellent choice for both small and large installations. It's fast, simple to set up, requires no special administration and it uses very little memory."
|
|
SECTION = "mail"
|
|
LICENSE = "LGPL-2.1-only & MIT"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=2956560272e5b31d9d64f03111732048"
|
|
|
|
SRC_URI = "http://dovecot.org/releases/2.3/dovecot-${PV}.tar.gz \
|
|
file://0001-configure.ac-convert-AC_TRY_RUN-to-AC_TRY_LINK-state.patch \
|
|
file://dovecot.service \
|
|
file://dovecot.socket \
|
|
file://0001-not-check-pandoc.patch \
|
|
file://0001-m4-Check-for-libunwind-instead-of-libunwind-generic.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "05b11093a71c237c2ef309ad587510721cc93bbee6828251549fc1586c36502d"
|
|
|
|
DEPENDS = "openssl xz zlib bzip2 libcap icu libtirpc bison-native"
|
|
CFLAGS += "-I${STAGING_INCDIR}/tirpc"
|
|
LDFLAGS += "-ltirpc"
|
|
|
|
inherit autotools pkgconfig systemd useradd gettext multilib_header
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'ldap pam systemd', d)}"
|
|
|
|
PACKAGECONFIG[pam] = "--with-pam,--without-pam,libpam,"
|
|
PACKAGECONFIG[systemd] = "--with-systemd,--without-systemd,systemd,"
|
|
PACKAGECONFIG[ldap] = "--with-ldap=plugin,--without-ldap,openldap,"
|
|
PACKAGECONFIG[lz4] = "--with-lz4,--without-lz4,lz4,"
|
|
|
|
# From native build in armv7a-hf/eglibc
|
|
CACHED_CONFIGUREVARS += "i_cv_signed_size_t=no \
|
|
i_cv_gmtime_max_time_t=32 \
|
|
i_cv_signed_time_t=yes \
|
|
i_cv_mmap_plays_with_write=yes \
|
|
i_cv_fd_passing=yes \
|
|
i_cv_c99_vsnprintf=yes \
|
|
lib_cv___va_copy=yes \
|
|
lib_cv_va_copy=yes \
|
|
lib_cv_va_val_copy=yes \
|
|
"
|
|
|
|
# hardcode epoll() to avoid running unsafe tests
|
|
# BSD needs kqueue and uclibc poll()
|
|
EXTRA_OECONF = " --with-ioloop=epoll"
|
|
|
|
SYSTEMD_PACKAGES = "${PN}"
|
|
SYSTEMD_SERVICE:${PN} = "dovecot.service dovecot.socket"
|
|
SYSTEMD_AUTO_ENABLE = "disable"
|
|
|
|
do_install:append () {
|
|
rm -rf ${D}${libdir}/dovecot/dovecot-config
|
|
install -d 755 ${D}/etc/dovecot
|
|
touch 644 ${D}/etc/dovecot/dovecot.conf
|
|
if [ "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}" ]; then
|
|
install -m 0644 ${WORKDIR}/dovecot.service ${D}${systemd_unitdir}/system
|
|
sed -i -e 's#@SYSCONFDIR@#${sysconfdir}#g' ${D}${systemd_unitdir}/system/dovecot.service
|
|
sed -i -e 's#@SBINDIR@#${sbindir}#g' ${D}${systemd_unitdir}/system/dovecot.service
|
|
fi
|
|
oe_multilib_header dovecot/config.h
|
|
}
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
USERADD_PARAM:${PN} = "-r -d ${libexecdir} -M -s ${base_sbindir}/nologin -g dovecot dovecot; \
|
|
-r -d ${libexecdir} -M -s ${base_sbindir}/nologin -g dovenull dovenull"
|
|
GROUPADD_PARAM:${PN} = "-f -r dovecot;-f -r dovenull"
|
|
|
|
FILES:${PN} += "${libdir}/dovecot/*plugin.so \
|
|
${libdir}/dovecot/libfs_compress.so \
|
|
${libdir}/dovecot/libssl_iostream_openssl.so"
|
|
FILES:${PN}-staticdev += "${libdir}/dovecot/*/*.a"
|
|
FILES:${PN}-dev += "${libdir}/dovecot/libdovecot*.so"
|
|
FILES:${PN}-dbg += "${libdir}/dovecot/*/.debug"
|
|
|
|
CVE_STATUS[CVE-2016-4983] = "not-applicable-platform: Affects only postinstall script on specific distribution."
|