mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-17 04:37:19 +00:00
Leon Anavi
87f7eb0aed
Add a new recipe for neatvnc v0.6.0, a liberally licensed VNC server library with a clean interface. It is required for building Weston with VNC backend. Please note that tls is not part of the default PACKAGECONFIG because it requires gnutls. However, to use properly VNC it should be enabled if building Weston 12 with VNC backend. Signed-off-by: Leon Anavi <leon.anavi@konsulko.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
41 lines
1.2 KiB
BlitzBasic
41 lines
1.2 KiB
BlitzBasic
SUMMARY = "A liberally licensed VNC server library"
|
|
DESCRIPTION = "This is a liberally licensed VNC server library that's intended to be fast and neat."
|
|
HOMEPAGE = "https://github.com/any1/neatvnc"
|
|
LICENSE = "ISC"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=94fc374e7174f41e3afe0f027ee59ff7"
|
|
|
|
SRC_URI = "git://github.com/any1/neatvnc;branch=master;protocol=https"
|
|
|
|
SRCREV = "8b3dc1ae6099dcfa73aec3ae11df2fdc58540d14"
|
|
|
|
PV = "0.6.0+git${SRCPV}"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
DEPENDS = "libdrm pixman aml zlib"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[tls] = "-Dtls=enabled,-Dtls=disabled,gnutls"
|
|
PACKAGECONFIG[jpeg] = "-Djpeg=enabled,-Djpeg=disabled,libjpeg-turbo"
|
|
PACKAGECONFIG[examples] = "-Dexamples=true,-Dexamples=false,libpng"
|
|
PACKAGECONFIG[benchmarks] = "-Dbenchmarks=true,-Dbenchmarks=false,libpng"
|
|
|
|
PACKAGE_BEFORE_PN += "${PN}-examples"
|
|
ALLOW_EMPTY:${PN}-examples = "1"
|
|
FILES:${PN}-examples = "${bindir}"
|
|
|
|
NEATVNC_EXAMPLES = "draw png-server"
|
|
|
|
inherit meson pkgconfig
|
|
|
|
do_install:append () {
|
|
if ${@bb.utils.contains('PACKAGECONFIG', 'examples', 'true', 'false', d)}; then
|
|
install -d ${D}${bindir}
|
|
for bin in ${NEATVNC_EXAMPLES}; do
|
|
install -m 0755 ${B}/examples/$bin ${D}${bindir}
|
|
done
|
|
fi
|
|
}
|
|
|
|
BBCLASSEXTEND = "native"
|