mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-15 16:07:26 +00:00
Peter Marko
a2623f24ac
Pick patches according to oe-core patch for this CVE in wpa-supplicant. Leave out commit which patched only files not present in hostapd. Note that Debian just picked the last commit (actually fixing the CVE) and removed not-applicable parts, but it is probably better to be consistent with oe-core status. Signed-off-by: Peter Marko <peter.marko@siemens.com> Signed-off-by: Anuj Mittal <anuj.mittal@oss.qualcomm.com>
66 lines
2.2 KiB
BlitzBasic
66 lines
2.2 KiB
BlitzBasic
SUMMARY = "User space daemon for extended IEEE 802.11 management"
|
|
HOMEPAGE = "http://w1.fi/hostapd/"
|
|
SECTION = "kernel/userland"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://hostapd/README;beginline=5;endline=47;md5=aa03b8bd6216d1a7ca01fd4b89863073"
|
|
|
|
DEPENDS = "libnl openssl"
|
|
|
|
SRC_URI = " \
|
|
http://w1.fi/releases/hostapd-${PV}.tar.gz \
|
|
file://defconfig \
|
|
file://init \
|
|
file://hostapd.service \
|
|
file://CVE-2024-3596_00.patch \
|
|
file://CVE-2024-3596_01.patch \
|
|
file://CVE-2024-3596_02.patch \
|
|
file://CVE-2024-3596_04.patch \
|
|
file://CVE-2024-3596_05.patch \
|
|
file://CVE-2024-3596_06.patch \
|
|
file://CVE-2024-3596_07.patch \
|
|
file://CVE-2024-3596_08.patch \
|
|
file://0001-SAE-Check-for-invalid-Rejected-Groups-element-length.patch \
|
|
file://0003-SAE-Reject-invalid-Rejected-Groups-element-in-the-pa.patch \
|
|
file://CVE-2023-52160.patch \
|
|
file://CVE-2025-24912_01.patch \
|
|
file://CVE-2025-24912_02.patch \
|
|
file://CVE-2022-37660-01.patch \
|
|
file://CVE-2022-37660-02.patch \
|
|
file://CVE-2022-37660-03.patch \
|
|
file://CVE-2022-37660-04.patch \
|
|
"
|
|
|
|
|
|
SRC_URI[sha256sum] = "206e7c799b678572c2e3d12030238784bc4a9f82323b0156b4c9466f1498915d"
|
|
|
|
inherit update-rc.d systemd pkgconfig features_check
|
|
|
|
CONFLICT_DISTRO_FEATURES = "openssl-no-weak-ciphers"
|
|
|
|
INITSCRIPT_NAME = "hostapd"
|
|
|
|
SYSTEMD_SERVICE:${PN} = "hostapd.service"
|
|
SYSTEMD_AUTO_ENABLE:${PN} = "disable"
|
|
|
|
do_configure:append() {
|
|
install -m 0644 ${WORKDIR}/defconfig ${B}/hostapd/.config
|
|
}
|
|
|
|
do_compile() {
|
|
export CFLAGS="-MMD -O2 -Wall -g"
|
|
export EXTRA_CFLAGS="${CFLAGS}"
|
|
make -C hostapd V=1
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}${sbindir} ${D}${sysconfdir}/init.d ${D}${systemd_unitdir}/system/
|
|
install -m 0644 ${B}/hostapd/hostapd.conf ${D}${sysconfdir}
|
|
install -m 0755 ${B}/hostapd/hostapd ${D}${sbindir}
|
|
install -m 0755 ${B}/hostapd/hostapd_cli ${D}${sbindir}
|
|
install -m 755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/hostapd
|
|
install -m 0644 ${WORKDIR}/hostapd.service ${D}${systemd_unitdir}/system/
|
|
sed -i -e 's,@SBINDIR@,${sbindir},g' -e 's,@SYSCONFDIR@,${sysconfdir},g' ${D}${systemd_unitdir}/system/hostapd.service
|
|
}
|
|
|
|
CONFFILES:${PN} += "${sysconfdir}/hostapd.conf"
|