mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-14 05:49:57 +00:00
Wang Mingyu
3864450575
Changelog: ============= -Disable flat_namespace to build libmpifort on macOS by default -Prefix warning messages with "MPICH" -Add --disable-doc configure option -Fix support for building MPICH Fortran support with Xcode 15 on macOS -Fix bug in MPI_WIN_SHARED_QUERY when window is not shared -Fix bug in ch4/ofi gpu pipelining -Fixes for Intel GPU support -Fix memory leak in ch4/shm collectives -Fix bug in MPI_COMM_SPLIT with intercommunicators and non-zero root -Fix bug in DAOS ROMIO driver -Fix bug in cycling error code array -Return an error if there is failure to create a datatype in mpi_f08 module for noncontiguous user data -Return an error when shared memory segment creation fails Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
68 lines
2.2 KiB
BlitzBasic
68 lines
2.2 KiB
BlitzBasic
SUMMARY = "Message Passing Interface (MPI) implementation"
|
|
HOMEPAGE = "http://www.mpich.org/"
|
|
SECTION = "devel"
|
|
|
|
LICENSE = "BSD-2-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=7a88f0d96d0d7396a7c66bf353235b62"
|
|
|
|
SRC_URI = "http://www.mpich.org/static/downloads/${PV}/mpich-${PV}.tar.gz"
|
|
SRC_URI[sha256sum] = "23331b2299f287c3419727edc2df8922d7e7abbb9fd0ac74e03b9966f9ad42d7"
|
|
|
|
RDEPENDS:${PN} += "bash perl libxml2"
|
|
|
|
EXTRA_OECONF = "--enable-debuginfo \
|
|
--enable-fast \
|
|
--enable-shared \
|
|
--with-pm=gforker \
|
|
BASH_SHELL='${USRBINPATH}/env bash' \
|
|
PERL='${USRBINPATH}/env perl' \
|
|
--with-device=ch3:nemesis \
|
|
"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
|
|
PACKAGECONFIG[cxx] = "--enable-cxx,--disable-cxx"
|
|
PACKAGECONFIG[fortran] = "--with-cross=${WORKDIR}/cross_values.txt --enable-fortran,--disable-f77 --disable-fortran,libgfortran"
|
|
|
|
# libmpi.so needs symbols like __multf3 and somehow it does not respect --rtlib option passed by clang
|
|
LDFLAGS:append:x86-64 = " -lgcc"
|
|
LDFLAGS:append:x86 = " -lgcc"
|
|
|
|
inherit autotools gettext pkgconfig qemu
|
|
|
|
DEPENDS += "qemu-native"
|
|
|
|
do_configure() {
|
|
if [ "${@bb.utils.contains('PACKAGECONFIG', 'fortran', '1', '', d)}" = "1" ]; then
|
|
qemu_binary="${@qemu_wrapper_cmdline(d, d.getVar('STAGING_DIR_HOST'), [d.expand('${STAGING_DIR_HOST}${libdir}'),d.expand('${STAGING_DIR_HOST}${base_libdir}')])}"
|
|
cat > ${WORKDIR}/qemuwrapper << EOF
|
|
#!/bin/sh
|
|
$qemu_binary "\$@"
|
|
EOF
|
|
chmod +x ${WORKDIR}/qemuwrapper
|
|
|
|
sed -i 's:my \(.*\) ./t`;:my \1 ${WORKDIR}/qemuwrapper ${WORKDIR}/t`;:' ${S}/maint/gen_cross.pl
|
|
|
|
cd ${WORKDIR}
|
|
perl ${S}/maint/gen_cross.pl
|
|
|
|
sed -i 's:\(CROSS_F90_INTEGER_MODEL_MAP=.*\) }"$:\1 }, ":' ${WORKDIR}/cross_values.txt
|
|
fi
|
|
|
|
cd ${S}
|
|
./autogen.sh
|
|
|
|
cd ${B}
|
|
oe_runconf
|
|
sed -i -e 's,${WORKDIR},,g' ${B}/src/include/mpichinfo.h
|
|
}
|
|
|
|
do_install:append() {
|
|
sed -i 's,${S}/,,g' ${D}/${libdir}/libmpi.la
|
|
sed -i 's,${DEBUG_PREFIX_MAP},,g' ${D}${bindir}/mpicxx
|
|
sed -i 's,${DEBUG_PREFIX_MAP},,g' ${D}${bindir}/mpicc
|
|
sed -i 's,${DEBUG_PREFIX_MAP},,g' ${D}/${libdir}/pkgconfig/mpich.pc
|
|
sed -i 's,${RECIPE_SYSROOT},/,g' ${D}${bindir}/mpicc
|
|
sed -i 's,${RECIPE_SYSROOT},/,g' ${D}${bindir}/mpicxx
|
|
}
|