mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-15 16:07:26 +00:00
Wang Mingyu
c50a209d31
Changelog: ========== * Adapt to the new way of handling the 2FA secret by the daemon, needed by it to fix a bug with certain clients. Requires NetworkManager >= 1.46.2. * Update Slovenian and Hungarian translations. Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
56 lines
1.7 KiB
BlitzBasic
56 lines
1.7 KiB
BlitzBasic
SUMMARY = "NetworkManager-openvpn-plugin"
|
|
SECTION = "net/misc"
|
|
|
|
LICENSE = "GPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=100d5a599bead70ddcd70dcd73f2e29c"
|
|
|
|
DEPENDS = "dbus dbus-glib networkmanager openvpn intltool-native glib-2.0-native"
|
|
|
|
GNOMEBASEBUILDCLASS = "autotools"
|
|
inherit gnomebase useradd gettext systemd
|
|
|
|
SRC_URI = "${GNOME_MIRROR}/NetworkManager-openvpn/${@gnome_verdir("${PV}")}/NetworkManager-openvpn-${PV}.tar.xz"
|
|
|
|
SRC_URI:append:libc-musl = "${@bb.utils.contains('DISTRO_FEATURES', 'ld-is-lld', ' file://0001-linker-scripts-Do-not-export-_IO_stdin_used.patch', '', d)}"
|
|
|
|
SRC_URI[sha256sum] = "903fd4c0aebd2aa7ac70c9d8c2bed8df922655d22d764514403566ae89b7e886"
|
|
|
|
S = "${WORKDIR}/NetworkManager-openvpn-${PV}"
|
|
|
|
# meta-gnome in layers is required using gnome:
|
|
PACKAGECONFIG[gnome] = "--with-gnome,--without-gnome,gtk+3 libnma libsecret"
|
|
|
|
do_configure:append() {
|
|
# network-manager-openvpn.metainfo.xml is created in source folder but
|
|
# compile expects it in build folder. As long as nobody comes up with a
|
|
# better solution just support build:
|
|
if [ -e ${S}/appdata/network-manager-openvpn.metainfo.xml ]; then
|
|
mkdir -p ${B}/appdata
|
|
cp -f ${S}/appdata/network-manager-openvpn.metainfo.xml ${B}/appdata/
|
|
fi
|
|
}
|
|
|
|
do_install:append () {
|
|
rm -rf ${D}${libdir}/NetworkManager/*.la
|
|
}
|
|
|
|
# Create user and group nm-openvpn that are needed since version 1.0.6
|
|
USERADD_PACKAGES = "${PN}"
|
|
USERADD_PARAM:${PN} = "--system nm-openvpn"
|
|
|
|
FILES:${PN} += " \
|
|
${datadir}/dbus-1 \
|
|
${datadir}/metainfo \
|
|
${libdir}/NetworkManager/*.so \
|
|
${nonarch_libdir}/NetworkManager/VPN/nm-openvpn-service.name \
|
|
"
|
|
|
|
FILES:${PN}-staticdev += " \
|
|
${libdir}/NetworkManager/*.a \
|
|
"
|
|
|
|
RDEPENDS:${PN} = " \
|
|
networkmanager \
|
|
openvpn \
|
|
"
|