mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-16 04:17:25 +00:00
Markus Volk
a17cc2d6bf
Version 46.2 ~~~~~~~~~~~~ Released: 2024-05-24 This is a stable release with the following changes: * Fix a crash when no appstream data is found * Correct app safety calculation * Correct Flatpak system and user apps recognition * Slightly speed-up rpm-ostree metadata refresh This release also updates translations: * Kabyle (Rachida SACI) * Portuguese (Hugo Carvalho) * Spanish (Daniel Mustieles) Signed-off-by: Markus Volk <f_l_k@t-online.de> Signed-off-by: Khem Raj <raj.khem@gmail.com>
44 lines
1.4 KiB
BlitzBasic
44 lines
1.4 KiB
BlitzBasic
SUMMARY = "GNOME Software allows users to easily find, discover and install apps."
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
GTKDOC_MESON_OPTION ?= "gtk_doc"
|
|
|
|
inherit gnomebase gsettings itstool gnome-help gtk-icon-cache gtk-doc mime mime-xdg gettext upstream-version-is-even features_check
|
|
|
|
REQUIRED_DISTRO_FEATURES = "x11 polkit systemd pam"
|
|
|
|
DEPENDS += " \
|
|
appstream \
|
|
gdk-pixbuf \
|
|
glib-2.0 \
|
|
glib-2.0-native \
|
|
gsettings-desktop-schemas \
|
|
gtk4 \
|
|
iso-codes \
|
|
json-glib \
|
|
libadwaita \
|
|
libgudev \
|
|
libsoup-3.0 \
|
|
libxmlb-native \
|
|
polkit \
|
|
"
|
|
|
|
RDEPENDS:${PN} = "iso-codes"
|
|
|
|
EXTRA_OEMESON += "-Dtests=false -Dsoup2=false"
|
|
|
|
SRC_URI[archive.sha256sum] = "e700cba287764f5e2255514e312e160550fdbf7a5d3fe16358bb6f7b6732b974"
|
|
|
|
PACKAGECONFIG ?= "flatpak"
|
|
PACKAGECONFIG[flatpak] = "-Dflatpak=true,-Dflatpak=false,flatpak ostree"
|
|
PACKAGECONFIG[snap] = "-Dsnap=true,-Dsnap=false,snapd-glib"
|
|
PACKAGECONFIG[gtk_doc] = "-Dgtk_doc=true,-Dgtk_doc=false,libxslt-native docbook-xsl-stylesheets"
|
|
PACKAGECONFIG[man] = "-Dman=true,-Dman=false,libxslt-native docbook-xsl-stylesheets"
|
|
PACKAGECONFIG[packagekit] = "-Dpackagekit=true,-Dpackagekit=false,gnome-packagekit,gnome-packagekit"
|
|
PACKAGECONFIG[fwupd] = "-Dfwupd=true,-Dfwupd=false,fwupd,fwupd"
|
|
PACKAGECONFIG[malcontent] = "-Dmalcontent=true,-Dmalcontent=false,malcontent"
|
|
|
|
FILES:${PN} += "${datadir}"
|
|
FILES:${PN}-dev += "${libdir}/gnome-software/libgnomesoftware.so"
|