mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-14 05:49:57 +00:00
Wang Mingyu
ada16eff73
0001-Actually-use-the-hint-space-instruction-to-strip-PAC.patch removed since it's inclued in 20250127.1 abseil-cpp/0004-abseil-ppc-fixes.patch refreshed for 20250127.1 Changelog: ============= - Added support for Bazel 8.0 - Added support for Bazel Platforms for better portability - Added ABSL_ATTRIBUTE_VIEW and ABSL_ATTRIBUTE_OWNER for diagnosing certain lifetime issues - Many performance improvements - A security issue in hash container create/resize has been fixed. Note that the latest patch releases for previous LTS versions also address this issue. - Bazel BUILD files now reference repositories by their canonical names from the Bazel Central Registry. Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
54 lines
1.7 KiB
BlitzBasic
54 lines
1.7 KiB
BlitzBasic
SUMMARY = "Abseil is a cpp library like STL"
|
|
DESCRIPTION = "Abseil provides pieces missing from the C++ standard. Contains \
|
|
additional useful libraries like algorithm, container, debugging, hash, memory, \
|
|
meta, numeric, strings, synchronization, time, types and utility."
|
|
HOMEPAGE = "https://abseil.io/"
|
|
SECTION = "libs"
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=df52c6edb7adc22e533b2bacc3bd3915"
|
|
|
|
SRCREV = "d9e4955c65cd4367dd6bf46f4ccb8cd3d100540b"
|
|
BRANCH = "lts_2025_01_27"
|
|
SRC_URI = "git://github.com/abseil/abseil-cpp;branch=${BRANCH};protocol=https \
|
|
file://0001-absl-always-use-asm-sgidefs.h.patch \
|
|
file://0002-Remove-maes-option-from-cross-compilation.patch \
|
|
file://0003-Remove-neon-option-from-cross-compilation.patch \
|
|
file://0004-abseil-ppc-fixes.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit cmake
|
|
|
|
EXTRA_OECMAKE = "-DBUILD_SHARED_LIBS=ON \
|
|
-DBUILD_TESTING=OFF \
|
|
-DABSL_ENABLE_INSTALL=ON \
|
|
"
|
|
|
|
SYSROOT_DIRS:append:class-nativesdk:mingw32 = " ${bindir}"
|
|
|
|
PACKAGES_DYNAMIC += "^libabsl-*"
|
|
PACKAGES_DYNAMIC:class-native = ""
|
|
|
|
PACKAGESPLITFUNCS =+ "split_dynamic_packages"
|
|
|
|
python split_dynamic_packages() {
|
|
libdir = d.getVar('libdir')
|
|
|
|
libpackages = do_split_packages(
|
|
d,
|
|
root=libdir,
|
|
file_regex=r'^libabsl_(.*)\.so\..*$',
|
|
output_pattern='libabsl-%s',
|
|
description="abseil shared library %s",
|
|
prepend=True,
|
|
extra_depends='',
|
|
)
|
|
if libpackages:
|
|
d.appendVar('RDEPENDS:' + d.getVar('PN'), ' ' + ' '.join(libpackages))
|
|
}
|
|
|
|
ALLOW_EMPTY:${PN} = "1"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|