mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-14 05:49:57 +00:00
Wang Mingyu
a1882f4b17
Changelog: ========== - Added Linux-specific build files and dropped unused 'long long' config tests - Documentation fixes - Fixed an issue when reporting errors with a 'NULL' options pointer - Fixed some compiler warnings - Fixed installation on MingW Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
32 lines
1.1 KiB
BlitzBasic
32 lines
1.1 KiB
BlitzBasic
DESCRIPTION = "Tiny XML Library"
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=86d3f3a95c324c9479bd8986968f4327"
|
|
HOMEPAGE = "https://www.msweet.org/mxml/"
|
|
BUGTRACKER = "https://github.com/michaelrsweet/mxml/issues"
|
|
|
|
SRC_URI = "git://github.com/michaelrsweet/mxml.git;branch=master;protocol=https"
|
|
SRCREV = "0d5afc4278d7a336d554602b951c2979c3f8f296"
|
|
S = "${WORKDIR}/git"
|
|
|
|
# Package does not support out of tree builds.
|
|
inherit autotools-brokensep
|
|
|
|
PACKAGECONFIG ??= "threads"
|
|
PACKAGECONFIG[threads] = "--enable-threads,--disable-threads"
|
|
|
|
# MXML uses autotools but it explicitly states it does not support autoheader.
|
|
EXTRA_AUTORECONF = "--exclude=autopoint,autoheader"
|
|
|
|
do_configure:prepend() {
|
|
# Respect optimization CFLAGS specified by OE.
|
|
sed -e 's/-Os -g//' -i ${S}/configure.ac
|
|
|
|
# Enable verbose compilation output. This is required for extra QA checks to work.
|
|
sed -e '/.SILENT:/d' -i ${S}/Makefile.in
|
|
}
|
|
|
|
do_install() {
|
|
# Package uses DSTROOT instread of standard DESTDIR to specify install location.
|
|
oe_runmake install DSTROOT=${D}
|
|
}
|