mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-14 05:49:57 +00:00
Hongxu Jia
9fce979252
In commit [9d1b81c dracut.sh: improve udevdir and systemdutildir fallback logic], it checked a common binary `collect' to localte udevdir. While upgrading systemd to 241, it dropped binary `collect'. [https://github.com/systemd/systemd/commit/a168792c2d95695fd30c0371d4b3890a9df1eafb] So check binary `ata_id' to instead. Signed-off-by: Hongxu Jia <hongxu.jia@windriver.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
71 lines
2.3 KiB
BlitzBasic
71 lines
2.3 KiB
BlitzBasic
SUMMARY = "Initramfs generator using udev"
|
|
HOMEPAGE = "https://dracut.wiki.kernel.org/index.php/Main_Page"
|
|
DESCRIPTION = "Dracut is an event driven initramfs infrastructure. dracut (the tool) is used to create an initramfs image by copying tools and files from an installed system and combining it with the dracut framework, usually found in /usr/lib/dracut/modules.d."
|
|
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
PE = "1"
|
|
PV = "049"
|
|
|
|
# v048 tag
|
|
SRCREV = "225e4b94cbdb702cf512490dcd2ad9ca5f5b22c1"
|
|
SRC_URI = "git://git.kernel.org/pub/scm/boot/dracut/dracut.git;protocol=http \
|
|
file://0001-util.h-include-sys-reg.h-when-libc-glibc.patch \
|
|
file://0001-dracut.sh-improve-udevdir.patch \
|
|
"
|
|
|
|
DEPENDS += "kmod"
|
|
DEPENDS_append_libc-musl = " fts"
|
|
|
|
inherit bash-completion pkgconfig
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
EXTRA_OECONF = "--prefix=${prefix} \
|
|
--libdir=${prefix}/lib \
|
|
--datadir=${datadir} \
|
|
--sysconfdir=${sysconfdir} \
|
|
--sbindir=${sbindir} \
|
|
--disable-documentation \
|
|
--bindir=${bindir} \
|
|
--includedir=${includedir} \
|
|
--localstatedir=${localstatedir} \
|
|
"
|
|
|
|
# RDEPEND on systemd optionally
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
|
|
PACKAGECONFIG[systemd] = "--with-systemdsystemunitdir=${systemd_unitdir}/system/,,,systemd"
|
|
|
|
EXTRA_OEMAKE += 'libdir=${prefix}/lib LDLIBS="${LDLIBS}"'
|
|
|
|
LDLIBS_append_libc-musl = " -lfts"
|
|
|
|
do_configure() {
|
|
./configure ${EXTRA_OECONF}
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake install DESTDIR=${D}
|
|
# Its Makefile uses cp -arx to install modules.d, so fix the owner
|
|
# to root:root
|
|
chown -R root:root ${D}/${prefix}/lib/dracut/modules.d
|
|
}
|
|
|
|
FILES_${PN} += "${prefix}/lib/kernel \
|
|
${prefix}/lib/dracut \
|
|
${systemd_unitdir} \
|
|
"
|
|
FILES_${PN}-dbg += "${prefix}/lib/dracut/.debug"
|
|
|
|
CONFFILES_${PN} += "${sysconfdir}/dracut.conf"
|
|
|
|
RDEPENDS_${PN} = "findutils cpio util-linux-blkid util-linux-getopt util-linux bash ldd"
|
|
|
|
# This could be optimized a bit, but let's avoid non-booting systems :)
|
|
RRECOMMENDS_${PN} = " \
|
|
kernel-modules \
|
|
busybox \
|
|
coreutils \
|
|
"
|