mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-27 07:57:27 +00:00
Fabio Berton
68443bd22e
- Remove json packageconfig. See commit: https://github.com/vincentbernat/lldpd/commit/06987a24ce053cbb57f8853bbf544bc7c067c8aa - Add patch to use mkdir from /bin/mkdir in systemd service. - Update from lldpd (0.9.8) * Changes: + "Station" capability is only set if no other bit is set. + Use ethtool to get permanent address for bonds and teams. This might provide different results than the previous method. Some devices may still use the previous method. + Don't run ethtool as root. Kernels older than 2.6.19 won't get link information anymore. + Add "configure system hostname ." option to not use a FQDN for system name. + Add "-f json0" to provide a more regular/machine-parsable output to JSON output, even when not compiled with --enable-json0. * Fixes: + Handle team interfaces like a bond. Real MAC address cannot be retrieved yet. - Updates from lldpd (0.9.7) * Changes: + Attach remote TTL to port instead of chassis. + JSON support is now built-in and unconditionally enabled. Use --enable-json0 to keep the pre-0.9.2 json-c format. + When logging to syslog and daemonizing, don't log to stderr. + vxlan interfaces are now ignored as they are multi-point interfaces. + Maximum number of neighbors for an interface is increased from 4 to 32. Signed-off-by: Fabio Berton <fabio.berton@ossystems.com.br> Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com> Signed-off-by: Joe MacDonald <joe_macdonald@mentor.com>
66 lines
2.4 KiB
BlitzBasic
66 lines
2.4 KiB
BlitzBasic
SUMMARY = "A 802.1ab implementation (LLDP) to help you locate neighbors of all your equipments"
|
|
SECTION = "net/misc"
|
|
LICENSE = "ISC"
|
|
LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/ISC;md5=f3b90e78ea0cffb20bf5cca7947a896d"
|
|
|
|
DEPENDS = "libbsd libevent"
|
|
|
|
SRC_URI = "\
|
|
http://media.luffy.cx/files/${BPN}/${BPN}-${PV}.tar.gz \
|
|
file://lldpd.init.d \
|
|
file://lldpd.default \
|
|
file://src-daemon-lldpd.service.in-Use-fixed-path-for-mkdir.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "8809600492f6b73149eb19158e819c1f"
|
|
SRC_URI[sha256sum] = "9ee494e91bc33938575b2c09b26188c486ef8eac6e2155d250c189cc4e988c4f"
|
|
|
|
inherit autotools update-rc.d useradd systemd pkgconfig bash-completion
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
USERADD_PARAM_${PN} = "--system -g lldpd --shell /bin/false lldpd"
|
|
GROUPADD_PARAM_${PN} = "--system lldpd"
|
|
|
|
EXTRA_OECONF += "--without-embedded-libevent \
|
|
--disable-oldies \
|
|
--with-privsep-user=lldpd \
|
|
--with-privsep-group=lldpd \
|
|
--with-systemdsystemunitdir=${systemd_system_unitdir} \
|
|
--without-sysusersdir \
|
|
"
|
|
|
|
PACKAGECONFIG ??= "cdp fdp edp sonmp lldpmed dot1 dot3"
|
|
PACKAGECONFIG[xml] = "--with-xml,--without-xml,libxm2"
|
|
PACKAGECONFIG[snmp] = "--with-snmp,--without-snmp,net-snmp"
|
|
PACKAGECONFIG[readline] = "--with-readline,--without-readline,readline"
|
|
PACKAGECONFIG[seccomp] = "--with-seccomp,--without-seccomp,libseccomp"
|
|
PACKAGECONFIG[cdp] = "--enable-cdp,--disable-cdp"
|
|
PACKAGECONFIG[fdp] = "--enable-fdp,--disable-fdp"
|
|
PACKAGECONFIG[edp] = "--enable-edp,--disable-edp"
|
|
PACKAGECONFIG[sonmp] = "--enable-sonmp,--disable-sonmp"
|
|
PACKAGECONFIG[lldpmed] = "--enable-lldpmed,--disable-lldpmed"
|
|
PACKAGECONFIG[dot1] = "--enable-dot1,--disable-dot1"
|
|
PACKAGECONFIG[dot3] = "--enable-dot3,--disable-dot3"
|
|
PACKAGECONFIG[custom] = "--enable-custom,--disable-custom"
|
|
|
|
INITSCRIPT_NAME = "lldpd"
|
|
INITSCRIPT_PARAMS = "defaults"
|
|
|
|
SYSTEMD_SERVICE_${PN} = "lldpd.service"
|
|
|
|
do_install_append() {
|
|
install -Dm 0755 ${WORKDIR}/lldpd.init.d ${D}${sysconfdir}/init.d/lldpd
|
|
install -Dm 0644 ${WORKDIR}/lldpd.default ${D}${sysconfdir}/default/lldpd
|
|
# Make an empty configuration file
|
|
touch ${D}${sysconfdir}/lldpd.conf
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-zsh-completion"
|
|
|
|
FILES_${PN} += "${libdir}/sysusers.d"
|
|
RDEPENDS_${PN} += "os-release"
|
|
|
|
FILES_${PN}-zsh-completion += "${datadir}/zsh/"
|
|
# FIXME: zsh is broken in meta-oe so this cannot be enabled for now
|
|
#RDEPENDS_${PN}-zsh-completion += "zsh"
|