mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-14 05:49:57 +00:00
Yi Zhao
6b88305138
ChangeLog: https://github.com/canonical/netplan/releases/tag/1.2 https://github.com/canonical/netplan/releases/tag/1.2.1 Signed-off-by: Yi Zhao <yi.zhao@windriver.com> Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
52 lines
1.8 KiB
BlitzBasic
52 lines
1.8 KiB
BlitzBasic
SUMMARY = "The network configuration abstraction renderer"
|
|
DESCRIPTION = "Netplan is a utility for easily configuring networking on a \
|
|
linux system. You simply create a YAML description of the required network \
|
|
interfaces and what each should be configured to do. From this description \
|
|
Netplan will generate all the necessary configuration for your chosen renderer \
|
|
tool."
|
|
HOMEPAGE = "https://netplan.io"
|
|
SECTION = "net/misc"
|
|
|
|
LICENSE = "GPL-3.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
|
|
|
|
inherit meson pkgconfig systemd python3targetconfig features_check
|
|
|
|
REQUIRED_DISTRO_FEATURES = "systemd"
|
|
|
|
SRC_URI = "git://github.com/CanonicalLtd/netplan.git;branch=main;protocol=https \
|
|
file://0001-meson.build-do-not-use-Werror.patch \
|
|
"
|
|
|
|
SRC_URI:append:libc-musl = " file://0001-don-t-fail-if-GLOB_BRACE-is-not-defined.patch"
|
|
|
|
SRCREV = "f758e3f6415aa68b7cf28991bc5b3e9631297d6d"
|
|
|
|
|
|
DEPENDS = "glib-2.0 libyaml util-linux-libuuid \
|
|
systemd python3-cffi-native \
|
|
"
|
|
|
|
EXTRA_OEMESON = "-Dtesting=false -Dunit_testing=false"
|
|
|
|
RDEPENDS:${PN} = "python3-core python3-netifaces python3-pyyaml \
|
|
python3-dbus python3-rich python3-cffi \
|
|
python3-json python3-fcntl \
|
|
util-linux-libuuid libnetplan \
|
|
"
|
|
|
|
do_install:append() {
|
|
install -d -m 755 ${D}${sysconfdir}/netplan
|
|
}
|
|
|
|
PACKAGES += "${PN}-dbus libnetplan"
|
|
|
|
FILES:libnetplan = "${libdir}/libnetplan.so.*"
|
|
FILES:${PN} = "${sbindir} ${libexecdir}/netplan/generate \
|
|
${libexecdir}/netplan/configure \
|
|
${datadir}/netplan ${datadir}/bash-completion \
|
|
${systemd_unitdir} ${PYTHON_SITEPACKAGES_DIR} \
|
|
${sysconfdir}/netplan \
|
|
"
|
|
FILES:${PN}-dbus = "${libexecdir}/netplan/netplan-dbus ${datadir}/dbus-1"
|