mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-13 17:39:57 +00:00
Alexander Kanavin
fc78d37ff0
Please see https://git.yoctoproject.org/poky/commit/?id=4dd321f8b83afecd962393101b2a6861275b5265 for what changes are needed, and sed commands that can be used to make them en masse. I've verified that bitbake -c patch world works with these, but did not run a world build; the majority of recipes shouldn't need further fixups, but if there are some that still fall out, they can be fixed in followups. Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Khem Raj <raj.khem@gmail.com>
31 lines
1.0 KiB
BlitzBasic
31 lines
1.0 KiB
BlitzBasic
DESCRIPTION = "Tiny XML Library"
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=86d3f3a95c324c9479bd8986968f4327"
|
|
HOMEPAGE = "https://www.msweet.org/mxml/"
|
|
BUGTRACKER = "https://github.com/michaelrsweet/mxml/issues"
|
|
|
|
SRC_URI = "git://github.com/michaelrsweet/mxml.git;branch=master;protocol=https"
|
|
SRCREV = "0d5afc4278d7a336d554602b951c2979c3f8f296"
|
|
|
|
# Package does not support out of tree builds.
|
|
inherit autotools-brokensep
|
|
|
|
PACKAGECONFIG ??= "threads"
|
|
PACKAGECONFIG[threads] = "--enable-threads,--disable-threads"
|
|
|
|
# MXML uses autotools but it explicitly states it does not support autoheader.
|
|
EXTRA_AUTORECONF = "--exclude=autopoint,autoheader"
|
|
|
|
do_configure:prepend() {
|
|
# Respect optimization CFLAGS specified by OE.
|
|
sed -e 's/-Os -g//' -i ${S}/configure.ac
|
|
|
|
# Enable verbose compilation output. This is required for extra QA checks to work.
|
|
sed -e '/.SILENT:/d' -i ${S}/Makefile.in
|
|
}
|
|
|
|
do_install() {
|
|
# Package uses DSTROOT instread of standard DESTDIR to specify install location.
|
|
oe_runmake install DSTROOT=${D}
|
|
}
|