mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-10-23 08:48:24 +00:00
Wang Mingyu
ac6d095e67
Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
(cherry picked from commit 7e505c3453)
Changelog:
https://github.com/michaelrsweet/mxml/releases/tag/v4.0.5
Signed-off-by: Ankur Tyagi <ankur.tyagi85@gmail.com>
Signed-off-by: Anuj Mittal <anuj.mittal@oss.qualcomm.com>
31 lines
1.0 KiB
BlitzBasic
31 lines
1.0 KiB
BlitzBasic
DESCRIPTION = "Tiny XML Library"
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=86d3f3a95c324c9479bd8986968f4327"
|
|
HOMEPAGE = "https://www.msweet.org/mxml/"
|
|
BUGTRACKER = "https://github.com/michaelrsweet/mxml/issues"
|
|
|
|
SRC_URI = "git://github.com/michaelrsweet/mxml.git;branch=master;protocol=https;tag=v${PV}"
|
|
SRCREV = "18d5c7dd9c71ebc1d3f21fe1e0614300babdda84"
|
|
|
|
# Package does not support out of tree builds.
|
|
inherit autotools-brokensep
|
|
|
|
PACKAGECONFIG ??= "threads"
|
|
PACKAGECONFIG[threads] = "--enable-threads,--disable-threads"
|
|
|
|
# MXML uses autotools but it explicitly states it does not support autoheader.
|
|
EXTRA_AUTORECONF = "--exclude=autopoint,autoheader"
|
|
|
|
do_configure:prepend() {
|
|
# Respect optimization CFLAGS specified by OE.
|
|
sed -e 's/-Os -g//' -i ${S}/configure.ac
|
|
|
|
# Enable verbose compilation output. This is required for extra QA checks to work.
|
|
sed -e '/.SILENT:/d' -i ${S}/Makefile.in
|
|
}
|
|
|
|
do_install() {
|
|
# Package uses DSTROOT instread of standard DESTDIR to specify install location.
|
|
oe_runmake install DSTROOT=${D}
|
|
}
|