mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-14 05:49:57 +00:00
Khem Raj
054804de14
toolchain-gcc override is only valid when meta-clang is included in layers, but this knob is actually needed for gcc to work, so having an empty override would not add this option while the default compiler remains gcc Signed-off-by: Khem Raj <raj.khem@gmail.com>
58 lines
1.9 KiB
BlitzBasic
58 lines
1.9 KiB
BlitzBasic
SUMMARY = "Free and Open On-Chip Debugging, In-System Programming and Boundary-Scan Testing"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
DEPENDS = "libusb-compat libftdi"
|
|
RDEPENDS_${PN} = "libusb1"
|
|
|
|
SRC_URI = " \
|
|
git://repo.or.cz/openocd.git;protocol=http;name=openocd \
|
|
git://repo.or.cz/r/git2cl.git;protocol=http;destsuffix=tools/git2cl;name=git2cl \
|
|
git://repo.or.cz/r/jimtcl.git;protocol=http;destsuffix=git/jimtcl;name=jimtcl \
|
|
git://repo.or.cz/r/libjaylink.git;protocol=http;destsuffix=git/src/jtag/drivers/libjaylink;name=libjaylink \
|
|
file://0001-esirisc_flash-Rename-PAGE_SIZE-to-FLASH_PAGE_SIZE.patch \
|
|
file://0001-Do-not-include-syscrtl.h-with-glibc.patch \
|
|
"
|
|
|
|
SRCREV_FORMAT = "openocd"
|
|
SRCREV_openocd = "7ee618692f56b0efea864890da45d73d28e393d9"
|
|
SRCREV_git2cl = "8373c9f74993e218a08819cbcdbab3f3564bbeba"
|
|
SRCREV_jimtcl = "a9bf5975fd0f89974d689a2d9ebd0873c8d64787"
|
|
SRCREV_libjaylink = "8645845c1abebd004e991ba9a7f808f4fd0c608b"
|
|
|
|
PV = "0.10+gitr${SRCPV}"
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit pkgconfig autotools-brokensep gettext
|
|
|
|
BBCLASSEXTEND += "nativesdk"
|
|
|
|
EXTRA_OECONF = "--enable-ftdi --disable-doxygen-html --disable-werror"
|
|
|
|
do_configure() {
|
|
./bootstrap nosubmodule
|
|
install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.guess ${S}/jimtcl/autosetup
|
|
install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.sub ${S}/jimtcl/autosetup
|
|
oe_runconf ${EXTRA_OECONF}
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake DESTDIR=${D} install
|
|
if [ -e "${D}${infodir}" ]; then
|
|
rm -Rf ${D}${infodir}
|
|
fi
|
|
if [ -e "${D}${mandir}" ]; then
|
|
rm -Rf ${D}${mandir}
|
|
fi
|
|
if [ -e "${D}${bindir}/.debug" ]; then
|
|
rm -Rf ${D}${bindir}/.debug
|
|
fi
|
|
}
|
|
|
|
FILES_${PN} = " \
|
|
${datadir}/openocd/* \
|
|
${bindir}/openocd \
|
|
"
|
|
|
|
PACKAGECONFIG[sysfsgpio] = "--enable-sysfsgpio,--disable-sysfsgpio"
|
|
PACKAGECONFIG ??= "sysfsgpio"
|