mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-15 16:07:26 +00:00
Anatol Belski
1636db7e6a
From: Anatol Belski <anbelski@microsoft.com> The libctmalloc-minimal is what is useful for C++ apps if only the improved allocator is needed. The gperftools package stays otherwise fully backward compatible as it's going to depend on libtcmalloc-minimal. The libtcmalloc-minimal can be installed separately, which allows for more flexibility and for cleaner image contents. The discussion on the patch https://patchwork.openembedded.org/patch/163234/ has shown, that a separate package for other libs might have less sense in this case, so it's not done. The patch 163234 can be abandoned in favor of this for now. Signed-off-by: Anatol Belski <anbelski@microsoft.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
39 lines
1.5 KiB
BlitzBasic
39 lines
1.5 KiB
BlitzBasic
SUMMARY = "Fast, multi-threaded malloc() and nifty performance analysis tools"
|
|
HOMEPAGE = "https://github.com/gperftools/gperftools"
|
|
LICENSE = "BSD"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=762732742c73dc6c7fbe8632f06c059a"
|
|
DEPENDS += "libunwind"
|
|
|
|
SRCREV = "9608fa3bcf8020d35f59fbf70cd3cbe4b015b972"
|
|
SRC_URI = "git://github.com/gperftools/gperftools \
|
|
file://0001-Support-Atomic-ops-on-clang.patch \
|
|
file://0001-fix-build-with-musl-libc.patch \
|
|
file://0001-disbale-heap-checkers-and-debug-allocator-on-musl.patch \
|
|
file://disable_libunwind_aarch64.patch \
|
|
file://sgidef.patch \
|
|
"
|
|
|
|
inherit autotools
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
# On mips, we have the following error.
|
|
# do_page_fault(): sending SIGSEGV to ls for invalid read access from 00000008
|
|
# Segmentation fault (core dumped)
|
|
COMPATIBLE_HOST_mipsarch_libc-glibc = "null"
|
|
# Disable thumb1
|
|
# {standard input}: Assembler messages:
|
|
# {standard input}:434: Error: lo register required -- `ldr pc,[sp]'
|
|
# Makefile:4538: recipe for target 'src/base/libtcmalloc_la-linuxthreads.lo' failed
|
|
ARM_INSTRUCTION_SET_armv5 = "arm"
|
|
ARM_INSTRUCTION_SET_toolchain-clang_arm = "arm"
|
|
|
|
# Ensure static libs are always enabled, as they seem to be not produced by
|
|
# default at least on ARM.
|
|
EXTRA_OECONF_append += " --enable-static"
|
|
|
|
PACKAGE_BEFORE_PN += "libtcmalloc-minimal"
|
|
FILES_libtcmalloc-minimal = "${libdir}/libtcmalloc_minimal*${SOLIBS} ${libdir}/libtcmalloc_minimal_debug*${SOLIBS}"
|
|
RDEPENDS_${PN} += "libtcmalloc-minimal (= ${EXTENDPKGV})"
|
|
|