mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-16 16:27:27 +00:00
Andre McCurdy
5ff5afa30b
- Backport Debian fix for "partial loss of message body, sending
message to wrong recipicients" issue:
https://sources.debian.net/patches/ssmtp/2.64-8/ssmtp-bug584162-fix.patch/
- Control ipv6 support based on ipv6 DISTRO feature.
- Enable ssl support by default (and add PACKAGECONFIG option to
control it).
- Drop inetutils dependency (inetutils provides only applications,
not libraries or header files, so a build dependency on it doesn't
make sense).
- Drop pkgconfig class (the ssmtp configure script etc doesn't make
any use of pkg-config).
Signed-off-by: Andre McCurdy <armccurdy@gmail.com>
Signed-off-by: Armin Kuster <akuster808@gmail.com>
Signed-off-by: Joe MacDonald <joe_macdonald@mentor.com>
36 lines
1.2 KiB
BlitzBasic
36 lines
1.2 KiB
BlitzBasic
SUMMARY = "extremely simple MTA to get mail off the system to a mail hub"
|
|
HOMEPAGE = "http://packages.qa.debian.org/s/ssmtp.html"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=0c56db0143f4f80c369ee3af7425af6e"
|
|
|
|
SRC_URI = "${DEBIAN_MIRROR}/main/s/${BPN}/${BPN}_${PV}.orig.tar.bz2 \
|
|
file://ssmtp-bug584162-fix.patch \
|
|
file://build-ouside_srcdir.patch \
|
|
file://use-DESTDIR.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "65b4e0df4934a6cd08c506cabcbe584f"
|
|
SRC_URI[sha256sum] = "22c37dc90c871e8e052b2cab0ad219d010fa938608cd66b21c8f3c759046fa36"
|
|
|
|
inherit autotools
|
|
|
|
PACKAGECONFIG ?= "ssl ${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)}"
|
|
|
|
PACKAGECONFIG[ssl] = "--enable-ssl,--disable-ssl,openssl"
|
|
PACKAGECONFIG[ipv6] = "--enable-inet6,--disable-inet6"
|
|
|
|
EXTRA_OECONF += "--mandir=${mandir}"
|
|
|
|
EXTRA_OEMAKE = "GEN_CONFIG='/bin/true'"
|
|
|
|
LDFLAGS += "${@bb.utils.contains('PACKAGECONFIG', 'ssl', '-lssl -lcrypto', '', d)}"
|
|
|
|
do_install_append () {
|
|
install -d ${D}${mandir}/
|
|
mv ${D}${exec_prefix}/man/* ${D}${mandir}/
|
|
rmdir ${D}${exec_prefix}/man
|
|
ln -s ssmtp ${D}${sbindir}/sendmail
|
|
ln -s ssmtp ${D}${sbindir}/newaliases
|
|
ln -s ssmtp ${D}${sbindir}/mailq
|
|
}
|