mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-10 16:40:03 +00:00
Oleksandr Kravchuk
01a7a78196
Signed-off-by: Oleksandr Kravchuk <open.source@oleksandr-kravchuk.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
34 lines
1.0 KiB
BlitzBasic
34 lines
1.0 KiB
BlitzBasic
SUMMARY = "Open client for Cisco AnyConnect VPN"
|
|
LICENSE = "LGPLv2.1"
|
|
LIC_FILES_CHKSUM = "file://COPYING.LGPL;md5=243b725d71bb5df4a1e5920b344b86ad"
|
|
|
|
SRC_URI = "git://git.infradead.org/users/dwmw2/openconnect.git"
|
|
SRCREV = "6487ee8763e1b6345718684909aca970befbc49d"
|
|
|
|
DEPENDS = "vpnc libxml2 krb5 gettext-native"
|
|
RDEPENDS_${PN} = "bash python"
|
|
|
|
PACKAGECONFIG ??= "gnutls lz4 libproxy"
|
|
|
|
# config defaults
|
|
PACKAGECONFIG[gnutls] = "--with-gnutls,--without-gnutls,gnutls,"
|
|
PACKAGECONFIG[lz4] = "--with-lz4,--without-lz4,lz4,"
|
|
PACKAGECONFIG[libproxy] = "--with-libproxy,--without-libproxy,libproxy,"
|
|
|
|
# not config defaults
|
|
PACKAGECONFIG[pcsc-lite] = "--with-libpcsclite,--without-libpcsclite,pcsc-lite,"
|
|
|
|
PV = "8.02"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools pkgconfig
|
|
|
|
EXTRA_OECONF += "--with-vpnc-script=${SYSROOT_DESTDIR}${sysconfdir}/vpnc/vpnc-script \
|
|
--disable-static"
|
|
|
|
do_configure_append() {
|
|
# script has /usr/bin/python2 path hardcoded
|
|
sed -i -e 's=python2\.*=python=g' ${S}/trojans/tncc-wrapper.py
|
|
}
|