mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-15 06:10:02 +00:00
Andreas Müller
3752d8f443
Seems they changed build so we have to build in-tree. With out of tree autotools build would break with: | glib-compile-resources --target=udisks-daemon-resources.h --generate-header --sourcedir=../../git udisks-daemon-resources.xml | glib-compile-resources --target=udisks-daemon-resources.c --generate-source --sourcedir=../../git udisks-daemon-resources.xml | Failed to open file “udisks-daemon-resources.xml”: No such file or directory Signed-off-by: Andreas Müller <schnitzeltony@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
57 lines
1.4 KiB
BlitzBasic
57 lines
1.4 KiB
BlitzBasic
SUMMARY = "udisks provides dbus interfaces for disks and storage devices"
|
|
LICENSE = "GPLv2+ & LGPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=dd79f6dbbffdbc8e86b086a8f0c0ef43"
|
|
|
|
DEPENDS = " \
|
|
glib-2.0-native \
|
|
libxslt-native \
|
|
acl \
|
|
libatasmart \
|
|
polkit \
|
|
libgudev \
|
|
glib-2.0 \
|
|
dbus-glib \
|
|
libblockdev \
|
|
"
|
|
DEPENDS += "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
|
|
|
|
RDEPENDS_${PN} = "acl"
|
|
|
|
SRC_URI = " \
|
|
git://github.com/storaged-project/udisks.git;branch=master \
|
|
"
|
|
PV = "2.9.1"
|
|
SRCREV = "95444ab6bf2b8d8c205b540dded4029fcb15f91b"
|
|
S = "${WORKDIR}/git"
|
|
|
|
CVE_PRODUCT = "udisks"
|
|
|
|
inherit autotools-brokensep systemd gtk-doc gobject-introspection gettext features_check
|
|
|
|
REQUIRED_DISTRO_FEATURES = "polkit"
|
|
|
|
EXTRA_OECONF = "--disable-man --disable-gtk-doc"
|
|
|
|
do_configure_prepend() {
|
|
# | configure.ac:656: error: required file 'build-aux/config.rpath' not found
|
|
mkdir -p ${S}/build-aux
|
|
touch ${S}/build-aux/config.rpath
|
|
}
|
|
|
|
FILES_${PN} += " \
|
|
${datadir}/dbus-1/ \
|
|
${datadir}/polkit-1 \
|
|
${datadir}/bash-completion \
|
|
${libdir}/polkit-1/extensions/*.so \
|
|
${nonarch_base_libdir}/udev/* \
|
|
${exec_prefix}${nonarch_base_libdir}/udisks2/* \
|
|
${systemd_system_unitdir} \
|
|
"
|
|
|
|
PACKAGES =+ "${PN}-libs"
|
|
FILES_${PN}-libs = "${libdir}/lib*${SOLIBS}"
|
|
FILES_${PN} += "${nonarch_libdir}/tmpfiles.d"
|
|
|
|
SYSTEMD_SERVICE_${PN} = "${BPN}.service"
|
|
SYSTEMD_AUTO_ENABLE = "disable"
|