mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-14 05:49:57 +00:00
Wang Mingyu
129bcf4a7e
From Poky 4.3, by default, usrmerge has been enabled. Some important binaries have been installed to /usr/sbin instead of /sbin such as init. So it is necessary to create symlinks from /usr/ to /, such as /usr/sbin to /sbin, /usr/bin to /bin. Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
48 lines
1.7 KiB
BlitzBasic
48 lines
1.7 KiB
BlitzBasic
SUMMARY = "A text-based user interface plugin of dnf for user to manage packages. "
|
|
LICENSE = "GPL-2.0-only"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
SRC_URI = "git://github.com/ubinux/dnf-plugin-tui.git;branch=master;protocol=https"
|
|
SRCREV = "baac322a8a6d57e62c703f6ed523152baec18b4f"
|
|
PV = "1.3"
|
|
|
|
SRC_URI:append:class-target = " file://oe-remote.repo.sample"
|
|
|
|
inherit setuptools3-base
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
do_install:append() {
|
|
install -d ${D}${datadir}/dnf
|
|
install -m 0755 ${S}/samples/* ${D}${datadir}/dnf
|
|
install -d ${D}${PYTHON_SITEPACKAGES_DIR}/dnf-plugins/mkimg
|
|
install -m 0755 ${S}/dnf-plugins/mkimg/* ${D}${PYTHON_SITEPACKAGES_DIR}/dnf-plugins/mkimg
|
|
for file in $(ls ${S}/dnf-plugins/ | grep -v mkimg); do
|
|
install -m 0755 ${S}/dnf-plugins/$file ${D}${PYTHON_SITEPACKAGES_DIR}/dnf-plugins
|
|
done
|
|
}
|
|
|
|
do_install:append:class-target() {
|
|
install -d ${D}${sysconfdir}/yum.repos.d
|
|
install -m 0644 ${WORKDIR}/oe-remote.repo.sample ${D}${sysconfdir}/yum.repos.d
|
|
}
|
|
|
|
do_install:append:class-nativesdk() {
|
|
install -d -p ${D}/${SDKPATH}/postinst-intercepts
|
|
cp -r ${COREBASE}/scripts/postinst-intercepts/* ${D}/${SDKPATH}/postinst-intercepts/
|
|
sed -i -e 's/STAGING_DIR_NATIVE/NATIVE_ROOT/g' ${D}/${SDKPATH}/postinst-intercepts/*
|
|
}
|
|
|
|
FILES:${PN} += "${datadir}/dnf"
|
|
FILES:${PN} += "${SDKPATH}/postinst-intercepts"
|
|
|
|
RDEPENDS:${PN} += " \
|
|
bash \
|
|
dnf \
|
|
libnewt-python \
|
|
"
|
|
DEPENDS:append:class-nativesdk = " file-replacement-nativesdk"
|
|
BBCLASSEXTEND = "nativesdk"
|
|
SKIP_RECIPE[dnf-plugin-tui] ?= "${@bb.utils.contains('PACKAGE_CLASSES', 'package_rpm', '', 'does not build correctly without package_rpm in PACKAGE_CLASSES', d)}"
|