mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-14 05:49:57 +00:00
zhengruoqin
d7d9597348
C++ Fix warnings raised by clang 11 (#8664) Make StringPiece constructible from std::string_view (#8707) Add missing capability attributes for LLVM 12 (#8714) Stop using std::iterator (deprecated in C++17). (#8741) Move field_access_listener from libprotobuf-lite to libprotobuf (#8775) Fix #7047 Safely handle setlocale (#8735) Remove deprecated version of SetTotalBytesLimit() (#8794) Support arena allocation of google::protobuf::AnyMetadata (#8758) Fix undefined symbol error around SharedCtor() (#8827) Fix default value of enum(int) in json_util with proto2 (#8835) Better Smaller ByteSizeLong Introduce event filters for inject_field_listener_events Reduce memory usage of DescriptorPool For lazy fields copy serialized form when allowed. Re-introduce the InlinedStringField class v2 access listener Reduce padding in the proto's ExtensionRegistry map. GetExtension performance optimizations Make tracker a static variable rather than call static functions Support extensions in field access listener Annotate MergeFrom for field access listener Fix incomplete types for field access listener Add map_entry/new_map_entry to SpecificField in MessageDifferencer. They record the map items which are different in MessageDifferencer's reporter. Reduce binary size due to fieldless proto messages TextFormat: ParseInfoTree supports getting field end location in addition to start. Fix repeated enum extension size in field listener Enable Any Text Expansion for Descriptors::DebugString() Switch from int{8,16,32,64} to int{8,16,32,64}_t Java Fix errorprone conflict (#8723) Removing deprecated TimeUtil class. (#8749) Optimized FieldDescriptor.valueOf() to avoid array copying. Removing deprecated TimeUtil class. Add Durations.parseUnchecked(String) and Timestamps.parseUnchecked(String) FieldMaskUtil: Add convenience method to mask the fields out of a given proto. JavaScript Optimize binary parsing of repeated float64 Fix for optimization when reading doubles from binary wire format Replace toArray implementation with toJSON. PHP Migrate PHP & Ruby to ABSL wyhash (#8854) Added support for PHP 8.1 (currently in RC1) to the C extension (#8964) Fixed PHP SEGV when constructing messages from a destructor. (#8969) Ruby Move DSL implementation from C to pure Ruby (#8850) Fixed a memory bug with RepeatedField#+. (#8970) Python Drops support for 2.7 and 3.5. Other [csharp] ByteString.CreateCodedInput should use ArraySegment offset and count (#8740) [ObjC] Add support for using the proto package to prefix symbols. (#8760) field_presence.md: fix Go example (#8788) Signed-off-by: Zheng Ruoqin <zhengrq.fnst@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
91 lines
3.0 KiB
BlitzBasic
91 lines
3.0 KiB
BlitzBasic
SUMMARY = "Protocol Buffers - structured data serialisation mechanism"
|
|
DESCRIPTION = "Protocol Buffers are a way of encoding structured data in an \
|
|
efficient yet extensible format. Google uses Protocol Buffers for almost \
|
|
all of its internal RPC protocols and file formats."
|
|
HOMEPAGE = "https://github.com/google/protobuf"
|
|
SECTION = "console/tools"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=37b5762e07f0af8c74ce80a8bda4266b"
|
|
|
|
DEPENDS = "zlib"
|
|
DEPENDS:append:class-target = " protobuf-native"
|
|
|
|
SRCREV = "89b14b1d16eba4d44af43256fc45b24a6a348557"
|
|
|
|
SRC_URI = "git://github.com/protocolbuffers/protobuf.git;branch=3.18.x \
|
|
file://run-ptest \
|
|
file://0001-protobuf-fix-configure-error.patch \
|
|
file://0001-Makefile.am-include-descriptor.cc-when-building-libp.patch \
|
|
file://0001-examples-Makefile-respect-CXX-LDFLAGS-variables-fix-.patch \
|
|
"
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools-brokensep pkgconfig ptest
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[python] = ",,"
|
|
|
|
EXTRA_OECONF += "--with-protoc=echo"
|
|
|
|
TEST_SRC_DIR = "examples"
|
|
LANG_SUPPORT = "cpp ${@bb.utils.contains('PACKAGECONFIG', 'python', 'python', '', d)}"
|
|
|
|
do_compile_ptest() {
|
|
mkdir -p "${B}/${TEST_SRC_DIR}"
|
|
|
|
# Add the location of the cross-compiled header and library files
|
|
# which haven't been installed yet.
|
|
cp "${B}/protobuf.pc" "${B}/${TEST_SRC_DIR}/protobuf.pc"
|
|
sed -e 's|libdir=|libdir=${PKG_CONFIG_SYSROOT_DIR}|' -i "${B}/${TEST_SRC_DIR}/protobuf.pc"
|
|
sed -e 's|Cflags:|Cflags: -I${S}/src|' -i "${B}/${TEST_SRC_DIR}/protobuf.pc"
|
|
sed -e 's|Libs:|Libs: -L${B}/src/.libs|' -i "${B}/${TEST_SRC_DIR}/protobuf.pc"
|
|
export PKG_CONFIG_PATH="${B}/${TEST_SRC_DIR}"
|
|
|
|
# Save the pkgcfg sysroot variable, and update it to nothing so
|
|
# that it doesn't append the sysroot to the beginning of paths.
|
|
# The header and library files aren't installed to the target
|
|
# system yet. So the absolute paths were specified above.
|
|
save_pkg_config_sysroot_dir=$PKG_CONFIG_SYSROOT_DIR
|
|
export PKG_CONFIG_SYSROOT_DIR=
|
|
|
|
# Compile the tests
|
|
for lang in ${LANG_SUPPORT}; do
|
|
oe_runmake -C "${S}/${TEST_SRC_DIR}" ${lang}
|
|
done
|
|
|
|
# Restore the pkgconfig sysroot variable
|
|
export PKG_CONFIG_SYSROOT_DIR=$save_pkg_config_sysroot_dir
|
|
}
|
|
|
|
do_install_ptest() {
|
|
local olddir=`pwd`
|
|
|
|
cd "${S}/${TEST_SRC_DIR}"
|
|
install -d "${D}/${PTEST_PATH}"
|
|
for i in add_person* list_people*; do
|
|
if [ -x "$i" ]; then
|
|
install "$i" "${D}/${PTEST_PATH}"
|
|
fi
|
|
done
|
|
cp "${S}/${TEST_SRC_DIR}/addressbook_pb2.py" "${D}/${PTEST_PATH}"
|
|
cd "$olddir"
|
|
}
|
|
|
|
PACKAGE_BEFORE_PN = "${PN}-compiler ${PN}-lite"
|
|
|
|
FILES:${PN}-compiler = "${bindir} ${libdir}/libprotoc${SOLIBS}"
|
|
FILES:${PN}-lite = "${libdir}/libprotobuf-lite${SOLIBS}"
|
|
|
|
RDEPENDS:${PN}-compiler = "${PN}"
|
|
RDEPENDS:${PN}-dev += "${PN}-compiler"
|
|
RDEPENDS:${PN}-ptest = "bash ${@bb.utils.contains('PACKAGECONFIG', 'python', 'python-protobuf', '', d)}"
|
|
|
|
MIPS_INSTRUCTION_SET = "mips"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
LDFLAGS:append:arm = " -latomic"
|
|
LDFLAGS:append:mips = " -latomic"
|
|
LDFLAGS:append:powerpc = " -latomic"
|
|
LDFLAGS:append:mipsel = " -latomic"
|