mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-15 06:10:02 +00:00
Johnathan Mantey
762a6880f3
The upstream ipmitool code has implemented an autoconfig control to enable and disable dynamic fetching of the IANA numbers file. As a result the patch removing the code that blocks fetching the IANA numbers is no longer relevant. The patch being removed explicitlly blocks downloading the IANA numbers file. Maintain this behavior at this level by using the --disable-registry-download feature. In order for that autoconfig switch to work, the recipe must inherit the pkgconfig feature. Without the pkgconfig dependency the code in the configure.ac file causes a compile time error. Tested: IANA numbers file isn't downloaded. Manually downloaded IANA file is installed in /usr/share/misc Enabling registry download enables dynamic download of IANA numbers Signed-off-by: Johnathan Mantey <johnathanx.mantey@intel.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
59 lines
2.4 KiB
BlitzBasic
59 lines
2.4 KiB
BlitzBasic
SUMMARY = "Utility for IPMI control"
|
|
DESCRIPTION = "This package contains a utility for interfacing with devices that support \
|
|
the Intelligent Platform Management Interface specification. IPMI is \
|
|
an open standard for machine health, inventory, and remote power control. \
|
|
\
|
|
This utility can communicate with IPMI-enabled devices through either a \
|
|
kernel driver such as OpenIPMI or over the RMCP LAN protocol defined in \
|
|
the IPMI specification. IPMIv2 adds support for encrypted LAN \
|
|
communications and remote Serial-over-LAN functionality. \
|
|
\
|
|
It provides commands for reading the Sensor Data Repository (SDR) and \
|
|
displaying sensor values, displaying the contents of the System Event \
|
|
Log (SEL), printing Field Replaceable Unit (FRU) information, reading and \
|
|
setting LAN configuration, and chassis power control. \
|
|
"
|
|
|
|
HOMEPAGE = "http://codeberg.org/IPMITool/ipmitool"
|
|
SECTION = "kernel/userland"
|
|
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=9aa91e13d644326bf281924212862184"
|
|
|
|
DEPENDS = "openssl readline ncurses"
|
|
SRCREV = "ab5ce5baff097ebb6e2a17a171858be213ee68d3"
|
|
SRC_URI = "git://codeberg.org/ipmitool/ipmitool;protocol=https;branch=master \
|
|
${IANA_ENTERPRISE_NUMBERS} \
|
|
"
|
|
IANA_ENTERPRISE_NUMBERS ?= ""
|
|
|
|
# Add these via bbappend if this database is needed by the system
|
|
#IANA_ENTERPRISE_NUMBERS = "http://www.iana.org/assignments/enterprise-numbers.txt;name=iana-enterprise-numbers;downloadfilename=iana-enterprise-numbers"
|
|
#SRC_URI[iana-enterprise-numbers.sha256sum] = "cdd97fc08325667434b805eb589104ae63f7a9eb720ecea73cb55110b383934c"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools pkgconfig
|
|
|
|
do_install:append() {
|
|
if [ -e ${WORKDIR}/iana-enterprise-numbers ]; then
|
|
install -Dm 0755 ${WORKDIR}/iana-enterprise-numbers ${D}${datadir}/misc/enterprise-numbers
|
|
fi
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-ipmievd"
|
|
FILES:${PN}-ipmievd += "${sbindir}/ipmievd"
|
|
FILES:${PN} += "${datadir}/misc"
|
|
|
|
# --disable-dependency-tracking speeds up the build
|
|
# --enable-file-security adds some security checks
|
|
# --disable-intf-free disables FreeIPMI support - we don't want to depend on
|
|
# FreeIPMI libraries, FreeIPMI has its own ipmitoool-like utility.
|
|
# --disable-registry-download prevents the IANA numbers from being fetched
|
|
# at build time, as it is not repeatable.
|
|
#
|
|
EXTRA_OECONF = "--disable-dependency-tracking --enable-file-security --disable-intf-free \
|
|
--disable-registry-download \
|
|
"
|
|
|