mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-12 17:20:13 +00:00
wangmy
2866fc83fd
ppc-musl.patch refreshed for new version. Changelog: ========== * Matt T. Proud contributed documentation fix to call Go programming language by it's true name instead of golang. * Robert Scott contributed debugallocator feature to use readable (PROT_READ) fence pages. This is activated by TCMALLOC_PAGE_FENCE_READABLE environment veriable. * User stdpain contributed fix for cmake detection of libunwind. * Natale Patriciello contributed fix for OSX Monterey support. * Volodymyr Nikolaichuk contributed support for returning memory back to OS by using mmap with MAP_FIXED and PROT_NONE. It is off by default and enabled by preprocessor define: FREE_MMAP_PROT_NONE. This should help OSes that don't support Linux-style madvise MADV_DONTNEED or BSD-style MADV_FREE. * Jingyun Hua has contributed basic support for LoongArch. * Github issue #1338 of failing to build on some recent musl versions has been fixed. * Github issue #1321 of failing to ship cmake bits with .tar.gz archive has been fixed. Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
68 lines
2.5 KiB
BlitzBasic
68 lines
2.5 KiB
BlitzBasic
SUMMARY = "Fast, multi-threaded malloc() and nifty performance analysis tools"
|
|
HOMEPAGE = "https://github.com/gperftools/gperftools"
|
|
DESCRIPTION = "The gperftools, previously called google-perftools, package contains some \
|
|
utilities to improve and analyze the performance of C++ programs. \
|
|
Included are an optimized thread-caching malloc() and cpu and heap profiling utilities. \
|
|
"
|
|
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=762732742c73dc6c7fbe8632f06c059a"
|
|
|
|
DEPENDS:append:libc-musl = " libucontext"
|
|
|
|
SRCREV = "bf8b714bf5075d0a6f2f28504b43095e2b1e11c5"
|
|
SRC_URI = "git://github.com/gperftools/gperftools;branch=master;protocol=https \
|
|
file://0001-Support-Atomic-ops-on-clang.patch \
|
|
file://0001-fix-build-with-musl-libc.patch \
|
|
file://0001-disbale-heap-checkers-and-debug-allocator-on-musl.patch \
|
|
file://disable_libunwind_aarch64.patch \
|
|
file://sgidef.patch \
|
|
"
|
|
|
|
SRC_URI:append:libc-musl = " file://ppc-musl.patch"
|
|
|
|
inherit autotools
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
# On mips, we have the following error.
|
|
# do_page_fault(): sending SIGSEGV to ls for invalid read access from 00000008
|
|
# Segmentation fault (core dumped)
|
|
COMPATIBLE_HOST:mipsarch = "null"
|
|
COMPATIBLE_HOST:riscv64 = "null"
|
|
COMPATIBLE_HOST:riscv32 = "null"
|
|
|
|
# Disable thumb1
|
|
# {standard input}: Assembler messages:
|
|
# {standard input}:434: Error: lo register required -- `ldr pc,[sp]'
|
|
# Makefile:4538: recipe for target 'src/base/libtcmalloc_la-linuxthreads.lo' failed
|
|
ARM_INSTRUCTION_SET:armv5 = "arm"
|
|
ARM_INSTRUCTION_SET:toolchain-clang:arm = "arm"
|
|
|
|
EXTRA_OECONF:append:libc-musl:powerpc64le = " --disable-cpu-profiler"
|
|
EXTRA_OECONF:append:libc-musl:powerpc = " --disable-cpu-profiler"
|
|
PACKAGECONFIG ?= "libunwind static"
|
|
PACKAGECONFIG:remove:arm:libc-musl = "libunwind"
|
|
PACKAGECONFIG:remove:riscv64 = "libunwind"
|
|
PACKAGECONFIG:remove:riscv32 = "libunwind"
|
|
|
|
PACKAGECONFIG[libunwind] = "--enable-libunwind,--disable-libunwind,libunwind"
|
|
PACKAGECONFIG[static] = "--enable-static,--disable-static,"
|
|
|
|
PACKAGE_BEFORE_PN += "libtcmalloc-minimal"
|
|
FILES:libtcmalloc-minimal = "${libdir}/libtcmalloc_minimal*${SOLIBS} ${libdir}/libtcmalloc_minimal_debug*${SOLIBS}"
|
|
|
|
# pprof tool requires Getopt::long and POSIX perl5 modules.
|
|
# Also runs `objdump` on each cpuprofile data file
|
|
RDEPENDS:${PN} += " \
|
|
binutils \
|
|
curl \
|
|
perl-module-carp \
|
|
perl-module-cwd \
|
|
perl-module-getopt-long \
|
|
perl-module-overloading \
|
|
perl-module-posix \
|
|
"
|
|
|
|
RDEPENDS:${PN} += "libtcmalloc-minimal (= ${EXTENDPKGV})"
|