mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-13 17:39:57 +00:00
Jan Vermaete
2cf01edb69
* Moved to the release archives instead of git. * Added the UPSTREAM_CHECK_URI. Note that the latest version of netdata is 1.31.0. But this one doesn't compile on Linux in cross compilation. The next version should have the fix. Signed-off-by: Jan Vermaete <jan.vermaete@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
66 lines
2.4 KiB
BlitzBasic
66 lines
2.4 KiB
BlitzBasic
HOMEPAGE = "https://github.com/netdata/netdata/"
|
|
SUMMARY = "Real-time performance monitoring"
|
|
DESCRIPTION = "Netdata is high-fidelity infrastructure monitoring and troubleshooting. \
|
|
Open-source, free, preconfigured, opinionated, and always real-time."
|
|
LICENSE = "GPLv3"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=fc9b848046ef54b5eaee6071947abd24"
|
|
|
|
SRC_URI = "https://github.com/netdata/netdata/releases/download/v${PV}/netdata-v${PV}.tar.gz"
|
|
SRC_URI[sha256sum] = "f169c8615a6823448c2f1923c87c286d798132ea29d26f366e96d26e0aec3697"
|
|
|
|
# default netdata.conf for netdata configuration
|
|
SRC_URI += "file://netdata.conf"
|
|
|
|
# file for providing systemd service support
|
|
SRC_URI += "file://netdata.service"
|
|
|
|
UPSTREAM_CHECK_URI = "https://github.com/netdata/netdata/releases"
|
|
|
|
S = "${WORKDIR}/netdata-v${PV}"
|
|
|
|
DEPENDS += "zlib util-linux libuv"
|
|
|
|
inherit pkgconfig autotools-brokensep useradd systemd
|
|
|
|
LIBS:toolchain-clang:x86 = "-latomic"
|
|
LIBS:riscv64 = "-latomic"
|
|
LIBS:riscv32 = "-latomic"
|
|
export LIBS
|
|
|
|
#systemd
|
|
SYSTEMD_PACKAGES = "${PN}"
|
|
SYSTEMD_SERVICE:${PN} = "netdata.service"
|
|
SYSTEMD_AUTO_ENABLE:${PN} = "enable"
|
|
|
|
#User specific
|
|
USERADD_PACKAGES = "${PN}"
|
|
USERADD_PARAM:${PN} = "--system --no-create-home --home-dir ${localstatedir}/run/netdata --user-group netdata"
|
|
|
|
do_install:append() {
|
|
#set S UID for plugins
|
|
chmod 4755 ${D}${libexecdir}/netdata/plugins.d/apps.plugin
|
|
|
|
if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
|
|
# Install systemd unit files
|
|
install -d ${D}${systemd_unitdir}/system
|
|
install -m 0644 ${WORKDIR}/netdata.service ${D}${systemd_unitdir}/system
|
|
sed -i -e 's,@@datadir,${datadir_native},g' ${D}${systemd_unitdir}/system/netdata.service
|
|
fi
|
|
|
|
# Install default netdata.conf
|
|
install -d ${D}${sysconfdir}/netdata
|
|
install -m 0644 ${WORKDIR}/netdata.conf ${D}${sysconfdir}/netdata/
|
|
sed -i -e 's,@@sysconfdir,${sysconfdir},g' ${D}${sysconfdir}/netdata/netdata.conf
|
|
sed -i -e 's,@@libdir,${libexecdir},g' ${D}${sysconfdir}/netdata/netdata.conf
|
|
sed -i -e 's,@@datadir,${datadir},g' ${D}${sysconfdir}/netdata/netdata.conf
|
|
|
|
install --group netdata --owner netdata --directory ${D}${localstatedir}/cache/netdata
|
|
install --group netdata --owner netdata --directory ${D}${localstatedir}/lib/netdata
|
|
|
|
chown -R netdata:netdata ${D}${datadir}/netdata/web
|
|
}
|
|
|
|
FILES_${PN} += "${localstatedir}/cache/netdata/ ${localstatedir}/lib/netdata/"
|
|
|
|
RDEPENDS:${PN} = "bash zlib"
|