mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-15 16:07:26 +00:00
Khem Raj
eff650e3f6
SRCREV_FORMAT should append to default for considering both git repositories. the git hook scripts require shell to be installed on target and it may want it from /usr/bin/sh and distro may not provide /usr/bin/sh since its not having usrmerge distro feature. Fixes ERROR: nlohmann-json-3.11.2-r0 do_package_qa: QA Issue: /usr/lib/nlohmann-json/ptest/json_test_data/.git/hooks/update.sample contained in package nlohmann-json-ptest requires /usr/bin/sh, but no providers found in RDEPENDS:nlohmann-json-ptest? [file-rdeps] Signed-off-by: Khem Raj <raj.khem@gmail.com>
48 lines
1.6 KiB
BlitzBasic
48 lines
1.6 KiB
BlitzBasic
SUMMARY = "JSON for modern C++"
|
|
HOMEPAGE = "https://nlohmann.github.io/json/"
|
|
SECTION = "libs"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE.MIT;md5=f969127d7b7ed0a8a63c2bbeae002588"
|
|
|
|
CVE_PRODUCT = "json-for-modern-cpp"
|
|
|
|
SRC_URI = "git://github.com/nlohmann/json.git;branch=develop;protocol=https \
|
|
git://github.com/nlohmann/json_test_data.git;destsuffix=git/json_test_data;name=json-test-data;branch=master;protocol=https \
|
|
file://0001-custom-allocators-define-missing-rebind-type-3895.patch \
|
|
file://0001-tests-unit-iterators2-use-std-ranges-equals-for-rang.patch \
|
|
file://run-ptest \
|
|
"
|
|
|
|
SRCREV = "bc889afb4c5bf1c0d8ee29ef35eaaf4c8bef8a5d"
|
|
SRCREV_json-test-data = "a1375cea09d27cc1c4cadb8d00470375b421ac37"
|
|
|
|
SRCREV_FORMAT .= "_json-test-data"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit cmake ptest
|
|
|
|
EXTRA_OECMAKE += "${@bb.utils.contains('PTEST_ENABLED', '1', '-DJSON_BuildTests=ON -DJSON_TestDataDirectory=${PTEST_PATH}/json_test_data', '-DJSON_BuildTests=OFF', d)}"
|
|
|
|
# nlohmann-json is a header only C++ library, so the main package will be empty.
|
|
ALLOW_EMPTY:${PN} = "1"
|
|
RDEPENDS:${PN}-dev = ""
|
|
RDEPENDS:${PN}-ptest = "perl"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
|
|
do_install_ptest () {
|
|
install -d ${D}${PTEST_PATH}/tests
|
|
cp -r ${S}/json_test_data/ ${D}${PTEST_PATH}/
|
|
cp -r ${B}/tests/test-* ${D}${PTEST_PATH}/tests
|
|
rm -rf ${D}${PTEST_PATH}/json_test_data/.git
|
|
}
|
|
|
|
|
|
# other packages commonly reference the file directly as "json.hpp"
|
|
# create symlink to allow this usage
|
|
do_install:append() {
|
|
ln -s nlohmann/json.hpp ${D}${includedir}/json.hpp
|
|
}
|