mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-05-10 06:09:36 +00:00
Amy Fong
14af1771aa
nodejs should use python from python-native package. On some hosts, the default python is missing bz2 support. Signed-off-by: Amy Fong <amy.fong@windriver.com> Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
45 lines
1.4 KiB
BlitzBasic
45 lines
1.4 KiB
BlitzBasic
SUMMARY = "nodeJS Evented I/O for V8 JavaScript"
|
|
HOMEPAGE = "http://nodejs.org"
|
|
LICENSE = "MIT & BSD"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=95a589a3257ab7dfe37d8a8379e3c72d"
|
|
|
|
DEPENDS = "openssl"
|
|
|
|
inherit pythonnative
|
|
|
|
SRC_URI = "http://nodejs.org/dist/v${PV}/node-v${PV}.tar.gz \
|
|
file://0001-gcc-has-a-builtin-define-to-denote-hard-abi-when-in-.patch \
|
|
"
|
|
SRC_URI[md5sum] = "25ed6aa5710ac46b867ff3f17a4da1d6"
|
|
SRC_URI[sha256sum] = "1d63dd42f9bd22f087585ddf80a881c6acbe1664891b1dda3b71306fe9ae00f9"
|
|
|
|
S = "${WORKDIR}/node-v${PV}"
|
|
|
|
# v8 errors out if you have set CCACHE
|
|
CCACHE = ""
|
|
|
|
ARCHFLAGS_arm = "${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', '--with-arm-float-abi=hard', '--with-arm-float-abi=softfp', d)}"
|
|
ARCHFLAGS ?= ""
|
|
|
|
# Node is way too cool to use proper autotools, so we install two wrappers to forcefully inject proper arch cflags to workaround gypi
|
|
do_configure () {
|
|
export LD="${CXX}"
|
|
|
|
./configure --prefix=${prefix} --without-snapshot ${ARCHFLAGS}
|
|
}
|
|
|
|
do_compile () {
|
|
export LD="${CXX}"
|
|
make BUILDTYPE=Release
|
|
}
|
|
|
|
do_install () {
|
|
oe_runmake install DESTDIR=${D}
|
|
}
|
|
|
|
RDEPENDS_${PN} = "curl python-shell python-datetime python-subprocess python-crypt python-textutils python-netclient "
|
|
RDEPENDS_${PN}_class-native = ""
|
|
|
|
FILES_${PN} += "${libdir}/node/wafadmin ${libdir}/node_modules ${libdir}/dtrace ${libdir}/*"
|
|
BBCLASSEXTEND = "native"
|