mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-13 17:39:57 +00:00
Sam Van Den Berge
51f98865da
See https://github.com/openembedded/meta-openembedded/issues/248 Signed-off-by: Sam Van Den Berge <sam.van.den.berge@telenet.be> Signed-off-by: Khem Raj <raj.khem@gmail.com>
69 lines
2.2 KiB
BlitzBasic
69 lines
2.2 KiB
BlitzBasic
SUMMARY = "Library for interfacing with IIO devices"
|
|
HOMEPAGE = "https://wiki.analog.com/resources/tools-software/linux-software/libiio"
|
|
SECTION = "libs"
|
|
LICENSE = "LGPLv2.1+"
|
|
LIC_FILES_CHKSUM = "file://COPYING.txt;md5=7c13b3376cea0ce68d2d2da0a1b3a72c"
|
|
|
|
SRCREV = "565bf68eccfdbbf22cf5cb6d792e23de564665c7"
|
|
PV = "0.21+git${SRCPV}"
|
|
|
|
SRC_URI = "git://github.com/analogdevicesinc/libiio.git;protocol=https"
|
|
UPSTREAM_CHECK_GITTAGREGEX = "v(?P<pver>\d+(\.\d+)+)"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
DISTUTILS_SETUP_PATH ?= "${B}/bindings/python/"
|
|
|
|
DEPENDS = " \
|
|
flex-native bison-native libaio \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'zeroconf', 'avahi', '', d)} \
|
|
"
|
|
|
|
inherit cmake python3native systemd setuptools3
|
|
|
|
EXTRA_OECMAKE = " \
|
|
-DCMAKE_BUILD_TYPE=RelWithDebInfo \
|
|
-DUDEV_RULES_INSTALL_DIR=${nonarch_base_libdir}/udev/rules.d \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '-DWITH_SYSTEMD=ON -DSYSTEMD_UNIT_INSTALL_DIR=${systemd_system_unitdir}', '', d)} \
|
|
"
|
|
|
|
PACKAGECONFIG ??= "usb_backend network_backend"
|
|
|
|
PACKAGECONFIG[usb_backend] = "-DWITH_USB_BACKEND=ON,-DWITH_USB_BACKEND=OFF,libusb1,libxml2"
|
|
PACKAGECONFIG[network_backend] = "-DWITH_NETWORK_BACKEND=ON,-DWITH_NETWORK_BACKEND=OFF,libxml2"
|
|
PACKAGECONFIG[libiio-python3] = "-DPYTHON_BINDINGS=ON,-DPYTHON_BINDINGS=OFF"
|
|
|
|
PACKAGES =+ "${PN}-iiod ${PN}-tests ${PN}-${PYTHON_PN}"
|
|
|
|
RDEPENDS_${PN}-${PYTHON_PN} = "${PN} ${PYTHON_PN}-ctypes ${PYTHON_PN}-stringold"
|
|
|
|
FILES_${PN}-iiod = " \
|
|
${sbindir}/iiod \
|
|
${systemd_system_unitdir}/iiod.service \
|
|
"
|
|
FILES_${PN}-tests = "${bindir}"
|
|
FILES_${PN}-${PYTHON_PN} = "${PYTHON_SITEPACKAGES_DIR}"
|
|
|
|
SYSTEMD_PACKAGES = "${PN}-iiod"
|
|
SYSTEMD_SERVICE_${PN}-iiod = "iiod.service"
|
|
|
|
# Explicitly define do_configure, do_compile and do_install because both cmake and setuptools3 have
|
|
# EXPORT_FUNCTIONS do_configure do_compile do_install
|
|
do_configure() {
|
|
cmake_do_configure
|
|
}
|
|
|
|
do_compile() {
|
|
if ${@bb.utils.contains('PACKAGECONFIG', 'libiio-python3', 'true', 'false', d)}; then
|
|
distutils3_do_compile
|
|
fi
|
|
cmake_do_compile
|
|
}
|
|
|
|
do_install() {
|
|
if ${@bb.utils.contains('PACKAGECONFIG', 'libiio-python3', 'true', 'false', d)}; then
|
|
distutils3_do_install
|
|
fi
|
|
cmake_do_install
|
|
}
|