mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-02-05 23:30:17 +00:00
6050beb4c3
The majority of the ptests require the data/ directory, so switch to using the git fetcher. Testsuite summary TOTAL: 1632 PASS: 1627 SKIP: 5 XFAIL: 0 FAIL: 0 XPASS: 0 ERROR: 0 DURATION: 268 Signed-off-by: Tim Orling <tim.orling@konsulko.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
47 lines
1.2 KiB
BlitzBasic
47 lines
1.2 KiB
BlitzBasic
SUMMARY = "orjson is a fast, correct JSON library for Python"
|
|
HOMEPAGE = "https://pypi.org/project/orjson/"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE-MIT;md5=b377b220f43d747efdec40d69fcaa69d"
|
|
|
|
SRCREV = "ec02024c3837255064f248c0d2d331319b75e9ad"
|
|
PYPI_SRC_URI = "git://github.com/ijl/orjson;protocol=https;branch=master;tag=${PV};destsuffix=orjson-${PV}"
|
|
|
|
CVE_PRODUCT = "orjson"
|
|
|
|
require ${BPN}-crates.inc
|
|
|
|
inherit pypi python_maturin cargo-update-recipe-crates ptest-python-pytest
|
|
|
|
SRC_URI += " \
|
|
file://0001-Guard-avx512-module-with-x86-target-cfg.patch \
|
|
file://0002-Guard-x86-feature-detection-macro-in-pystrref-object.patch \
|
|
"
|
|
DEPENDS = "python3-maturin-native"
|
|
|
|
RDEPENDS:${PN} += "python3-maturin python3-mypy"
|
|
|
|
do_compile:prepend() {
|
|
sed -i "/panic = \"abort\"/d" ${S}/Cargo.toml
|
|
}
|
|
|
|
do_install_ptest:append() {
|
|
install -d ${D}${PTEST_PATH}/data
|
|
cp -rf ${S}/data/* ${D}${PTEST_PATH}/data/
|
|
install -d ${D}${PTEST_PATH}/test
|
|
cp -rf ${S}/test/* ${D}${PTEST_PATH}/test/
|
|
}
|
|
|
|
RDEPENDS:${PN}-ptest += "\
|
|
python3-dateutil \
|
|
python3-dateutil-zoneinfo \
|
|
python3-faker \
|
|
python3-numpy \
|
|
python3-pandas \
|
|
python3-pendulum \
|
|
python3-psutil \
|
|
python3-pytz \
|
|
python3-tzdata \
|
|
"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|