mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-27 20:07:25 +00:00
changqing.li@windriver.com
7041cdd3b4
1. add submodule drbd-headers into SRC_URI drbd-headers is git submodule of drbd-utils, so drbd-headers's code will not fetch during do_fetch. but it will get during do_compile(there is a logic in drbd-utils's makefile to do this), but if during do_compile, network is broken, fetch drbd-headers will fail, then do_compile will fail since missing header file. 2. add patch for fix drbd init script Signed-off-by: Changqing Li <changqing.li@windriver.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
53 lines
2.0 KiB
BlitzBasic
53 lines
2.0 KiB
BlitzBasic
SUMMARY = "Distributed block device driver for Linux"
|
|
DESCRIPTION = "DRBD mirrors a block device over the network to another machine.\
|
|
DRBD mirrors a block device over the network to another machine.\
|
|
Think of it as networked raid 1. It is a building block for\
|
|
setting up high availability (HA) clusters."
|
|
HOMEPAGE = "http://www.drbd.org/"
|
|
SECTION = "admin"
|
|
LICENSE = "GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=5574c6965ae5f583e55880e397fbb018"
|
|
|
|
SRC_URI = "git://github.com/LINBIT/drbd-utils;name=drbd-utils \
|
|
git://github.com/LINBIT/drbd-headers;name=drbd-headers;destsuffix=git/drbd-headers \
|
|
file://0001-drbd-drbd-tools-only-rmmod-if-DRBD-is-a-module.patch \
|
|
"
|
|
# v9.4.0
|
|
SRCREV_drbd-utils = "eff6423ee72931aa0f8d0eb51742acee7c7cd3e1"
|
|
SRCREV_drbd-headers = "d9ef0576d0f29992e0539ed7ca14d4f12658cd25"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
UPSTREAM_CHECK_URI = "https://github.com/LINBIT/drbd-utils/releases"
|
|
|
|
SYSTEMD_SERVICE_${PN} = "drbd.service"
|
|
SYSTEMD_AUTO_ENABLE = "disable"
|
|
|
|
inherit autotools-brokensep systemd
|
|
|
|
EXTRA_OECONF = " \
|
|
--with-initdir=/etc/init.d \
|
|
--without-pacemaker \
|
|
--without-rgmanager \
|
|
--without-bashcompletion \
|
|
--with-distro debian \
|
|
--with-initscripttype=both \
|
|
--with-systemdunitdir=${systemd_unitdir}/system \
|
|
--without-manual\
|
|
"
|
|
|
|
do_install_append() {
|
|
# don't install empty /var/lock to avoid conflict with base-files
|
|
rm -rf ${D}${localstatedir}/lock
|
|
}
|
|
|
|
RDEPENDS_${PN} += "bash perl-module-getopt-long perl-module-exporter perl-module-constant perl-module-overloading perl-module-exporter-heavy"
|
|
|
|
# The drbd items are explicitly put under /lib when installed.
|
|
#
|
|
FILES_${PN} += "/run"
|
|
FILES_${PN} += "${nonarch_base_libdir}/drbd \
|
|
${nonarch_libdir}/drbd \
|
|
${nonarch_libdir}/tmpfiles.d"
|
|
FILES_${PN}-dbg += "${nonarch_base_libdir}/drbd/.debug"
|