mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-14 17:59:59 +00:00
Robert Yang
2037afbc32
* Remove 0001-Support-Atomic-ops-on-clang.patch because of: commit 54605b8a5807fe893a4b9ff8def982a264cdc6c9 Author: Aliaksey Kandratsenka <alkondratenko@gmail.com> Date: Wed Jun 21 10:39:18 2023 -0400 amputate old atomic ops implementation * Remove sgidef.patch because of: commit e78238d94d41764dc72edb37e3d6510255d3dcd4 Author: Aliaksey Kandratsenka <alkondratenko@gmail.com> Date: Wed Jun 21 10:39:38 2023 -0400 reworked heap leak checker for more portability * Remove 0001-Define-off64_t-as-off_t-on-musl.patch because of: commit 8be84e4a5c28c33bfdb7da3ee0c92d9620cd552f Author: Aliaksey Kandratsenka <alkondratenko@gmail.com> Date: Fri Jul 21 14:18:12 2023 -0400 drop old mmap hooks and introduce internal & simpler mmap_hook.h * Rebased 0001-Support-Atomic-ops-on-clang.patch for 2.15 * Rebased ppc-musl.patch for 2.15 * Add 0001-src-mmap_hook.cc-Fix-build-for-32bit-machine.patch to fix build error for 32bit machine. Signed-off-by: Robert Yang <liezhi.yang@windriver.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
66 lines
2.4 KiB
BlitzBasic
66 lines
2.4 KiB
BlitzBasic
SUMMARY = "Fast, multi-threaded malloc() and nifty performance analysis tools"
|
|
HOMEPAGE = "https://github.com/gperftools/gperftools"
|
|
DESCRIPTION = "The gperftools, previously called google-perftools, package contains some \
|
|
utilities to improve and analyze the performance of C++ programs. \
|
|
Included are an optimized thread-caching malloc() and cpu and heap profiling utilities. \
|
|
"
|
|
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=762732742c73dc6c7fbe8632f06c059a"
|
|
|
|
DEPENDS:append:libc-musl = " libucontext"
|
|
|
|
SRCREV = "365060c4213a48adb27f63d5dfad41b3dfbdd62e"
|
|
SRC_URI = "git://github.com/gperftools/gperftools;branch=master;protocol=https \
|
|
file://0001-disbale-heap-checkers-and-debug-allocator-on-musl.patch \
|
|
file://disable_libunwind_aarch64.patch \
|
|
file://0001-src-mmap_hook.cc-Fix-build-for-32bit-machine.patch \
|
|
"
|
|
|
|
SRC_URI:append:libc-musl = " file://ppc-musl.patch"
|
|
|
|
inherit autotools
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
# On mips, we have the following error.
|
|
# do_page_fault(): sending SIGSEGV to ls for invalid read access from 00000008
|
|
# Segmentation fault (core dumped)
|
|
COMPATIBLE_HOST:mipsarch = "null"
|
|
COMPATIBLE_HOST:riscv64 = "null"
|
|
COMPATIBLE_HOST:riscv32 = "null"
|
|
|
|
# Disable thumb1
|
|
# {standard input}: Assembler messages:
|
|
# {standard input}:434: Error: lo register required -- `ldr pc,[sp]'
|
|
# Makefile:4538: recipe for target 'src/base/libtcmalloc_la-linuxthreads.lo' failed
|
|
ARM_INSTRUCTION_SET:armv5 = "arm"
|
|
ARM_INSTRUCTION_SET:toolchain-clang:arm = "arm"
|
|
|
|
EXTRA_OECONF:append:libc-musl:powerpc64le = " --disable-cpu-profiler"
|
|
EXTRA_OECONF:append:libc-musl:powerpc = " --disable-cpu-profiler"
|
|
PACKAGECONFIG ?= "libunwind static"
|
|
PACKAGECONFIG:remove:arm:libc-musl = "libunwind"
|
|
PACKAGECONFIG:remove:riscv64 = "libunwind"
|
|
PACKAGECONFIG:remove:riscv32 = "libunwind"
|
|
|
|
PACKAGECONFIG[libunwind] = "--enable-libunwind,--disable-libunwind,libunwind"
|
|
PACKAGECONFIG[static] = "--enable-static,--disable-static,"
|
|
|
|
PACKAGE_BEFORE_PN += "libtcmalloc-minimal"
|
|
FILES:libtcmalloc-minimal = "${libdir}/libtcmalloc_minimal*${SOLIBS} ${libdir}/libtcmalloc_minimal_debug*${SOLIBS}"
|
|
|
|
# pprof tool requires Getopt::long and POSIX perl5 modules.
|
|
# Also runs `objdump` on each cpuprofile data file
|
|
RDEPENDS:${PN} += " \
|
|
binutils \
|
|
curl \
|
|
perl-module-carp \
|
|
perl-module-cwd \
|
|
perl-module-getopt-long \
|
|
perl-module-overloading \
|
|
perl-module-posix \
|
|
"
|
|
|
|
RDEPENDS:${PN} += "libtcmalloc-minimal (= ${EXTENDPKGV})"
|