mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-12 17:20:13 +00:00
Paul Barker
7d3febb7d3
Replace version 7.2.446 with the latest version currently available, 7.3.905. The old fetch method was inefficient as version 7.2 was downloaded and patches applied to get to version 7.2.446. Attempting this method with git 7.3 did not work as not all 905 patches applied cleanly. Instead we fetch version 7.3.905 directly from the upstream mercurial repository. This causes an implicit dependency on mercurial-native for the build which is reasonable considering that not many images include vim by default. The previously used patch configure.in_remove_CC_quotes.patch is still required as these changes haven't been made upstream; this patch still applies cleanly. Signed-off-by: Paul Barker <paul@paulbarker.me.uk> Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
79 lines
2.4 KiB
PHP
79 lines
2.4 KiB
PHP
DESCRIPTION = "Vi IMproved - enhanced vi editor"
|
|
SECTION = "console/utils"
|
|
DEPENDS = "ncurses"
|
|
# vimdiff doesn't like busybox diff
|
|
RSUGGESTS_${PN} = "diffutils"
|
|
LICENSE = "vim"
|
|
LIC_FILES_CHKSUM = "file://../runtime/doc/uganda.txt;md5=4c91d841bb7b75f68b5bb8ad7118f5b8"
|
|
|
|
PV_MAJOR = "${@d.getVar('PV',1).split('.')[0]}.${@d.getVar('PV',1).split('.')[1]}"
|
|
VIMDIR = "${PN}${@d.getVar('PV',1).split('.')[0]}${@d.getVar('PV',1).split('.')[1]}"
|
|
|
|
INC_PR = "r13"
|
|
|
|
SRC_URI = "hg://vim.googlecode.com/hg/;protocol=https;module=vim"
|
|
|
|
S = "${WORKDIR}/${PN}/src"
|
|
|
|
inherit autotools update-alternatives
|
|
|
|
# vim configure.in contains functions which got 'dropped' by autotools.bbclass
|
|
do_configure () {
|
|
rm -f auto/*
|
|
touch auto/config.mk
|
|
aclocal
|
|
autoconf
|
|
oe_runconf
|
|
touch auto/configure
|
|
touch auto/config.mk auto/config.h
|
|
}
|
|
|
|
#Available PACKAGECONFIG options are gtkgui, x11, tiny
|
|
PACKAGECONFIG ??= ""
|
|
|
|
PACKAGECONFIG[gtkgui] = "--enable-gtk2-test --enable-gui=gtk2,--enable-gui=no,gtk+,"
|
|
PACKAGECONFIG[x11] = "--with-x,--without-x,xt,"
|
|
PACKAGECONFIG[tiny] = "--with-features=tiny,--with-features=big,,"
|
|
|
|
EXTRA_OECONF = " \
|
|
--disable-gpm \
|
|
--disable-gtktest \
|
|
--disable-xim \
|
|
--disable-netbeans \
|
|
--with-tlib=ncurses \
|
|
ac_cv_small_wchar_t=no \
|
|
vim_cv_getcwd_broken=no \
|
|
vim_cv_memmove_handles_overlap=yes \
|
|
vim_cv_stat_ignores_slash=no \
|
|
vim_cv_terminfo=yes \
|
|
vim_cv_tgent=non-zero \
|
|
vim_cv_toupper_broken=no \
|
|
vim_cv_tty_group=world \
|
|
STRIP=/bin/true \
|
|
"
|
|
|
|
do_install_append() {
|
|
# Work around rpm picking up csh as a dep
|
|
chmod -x ${D}${datadir}/${PN}/${VIMDIR}/tools/vim132
|
|
|
|
# Install example vimrc from runtime files
|
|
install -m 0644 ../runtime/vimrc_example.vim ${D}/${datadir}/${PN}/vimrc
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-common ${PN}-syntax ${PN}-help ${PN}-tutor ${PN}-vimrc ${PN}-data"
|
|
FILES_${PN}-syntax = "${datadir}/${PN}/${VIMDIR}/syntax"
|
|
FILES_${PN}-help = "${datadir}/${PN}/${VIMDIR}/doc"
|
|
FILES_${PN}-tutor = "${datadir}/${PN}/${VIMDIR}/tutor ${bindir}/${PN}tutor"
|
|
FILES_${PN}-vimrc = "${datadir}/${PN}/vimrc"
|
|
FILES_${PN}-data = "${datadir}/${PN}"
|
|
|
|
# Recommend that runtime data is installed along with vim
|
|
RRECOMMENDS_${PN} = "${PN}-syntax ${PN}-help ${PN}-tutor ${PN}-vimrc ${PN}-data"
|
|
|
|
ALTERNATIVE_${PN} = "vi"
|
|
ALTERNATIVE_TARGET[vi] = "${bindir}/${PN}"
|
|
ALTERNATIVE_LINK_NAME[vi] = "${base_bindir}/vi"
|
|
ALTERNATIVE_PRIORITY[vi] = "100"
|
|
|
|
PARALLEL_MAKE = ""
|