mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-14 17:59:59 +00:00
Virendra Thakur
6ca163ed3e
Enable ptest for libssh , this change is backported from upstream scarthgap. Reference: https://git.openembedded.org/meta-openembedded/commit/?h=scarthgap&id=bf49bdea290ba8cf18f3fd6b47d1d71dfe499948 ~ # ptest-runner libssh START: ptest-runner 2025-01-28T14:28 BEGIN: /usr/lib/libssh/ptest PASS: torture_buffer PASS: torture_callbacks PASS: torture_channel PASS: torture_config PASS: torture_crypto PASS: torture_hashes PASS: torture_init PASS: torture_isipaddr PASS: torture_keyfiles PASS: torture_knownhosts_parsing PASS: torture_list PASS: torture_misc PASS: torture_options PASS: torture_packet PASS: torture_packet_filter PASS: torture_pki PASS: torture_pki_ecdsa PASS: torture_pki_ed25519 PASS: torture_pki_rsa PASS: torture_rand PASS: torture_threads_buffer PASS: torture_threads_crypto PASS: torture_threads_init PASS: torture_threads_pki_rsa DURATION: 119 END: /usr/lib/libssh/ptest 2025-01-28T14:29 STOP: ptest-runner TOTAL: 1 FAIL: 0 Signed-off-by: Virendra Thakur <virendrak@kpit.com> Signed-off-by: Armin Kuster <akuster808@gmail.com>
63 lines
2.0 KiB
BlitzBasic
63 lines
2.0 KiB
BlitzBasic
SUMMARY = "Multiplatform C library implementing the SSHv2 and SSHv1 protocol"
|
|
HOMEPAGE = "http://www.libssh.org"
|
|
SECTION = "libs"
|
|
LICENSE = "LGPL-2.1-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=dabb4958b830e5df11d2b0ed8ea255a0"
|
|
|
|
DEPENDS = "zlib openssl"
|
|
|
|
SRC_URI = "git://git.libssh.org/projects/libssh.git;protocol=https;branch=stable-0.8 \
|
|
file://CVE-2020-16135.patch \
|
|
file://CVE-2023-48795-1.patch \
|
|
file://CVE-2023-48795-2.patch \
|
|
file://CVE-2023-48795-3.patch \
|
|
file://0001-config-Move-common-parser-functions-to-config_parser.patch \
|
|
file://001_CVE-2023-6004.patch \
|
|
file://002_CVE-2023-6004.patch \
|
|
file://003_CVE-2023-6004.patch \
|
|
file://004_CVE-2023-6004.patch \
|
|
file://005_CVE-2023-6004.patch \
|
|
file://006_CVE-2023-6004.patch \
|
|
file://0001-tests-CMakeLists.txt-do-not-search-ssh-sshd-commands.patch \
|
|
file://run-ptest \
|
|
"
|
|
SRCREV = "04685a74df9ce1db1bc116a83a0da78b4f4fa1f8"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit cmake ptest
|
|
|
|
PACKAGECONFIG ??= "gcrypt ${@bb.utils.contains('PTEST_ENABLED', '1', 'tests', '', d)}"
|
|
PACKAGECONFIG[gssapi] = "-DWITH_GSSAPI=1, -DWITH_GSSAPI=0, krb5, "
|
|
PACKAGECONFIG[gcrypt] = "-DWITH_GCRYPT=1, -DWITH_GCRYPT=0, libgcrypt, "
|
|
PACKAGECONFIG[tests] = "-DUNIT_TESTING=1, -DUNIT_TESTING=0, cmocka"
|
|
ARM_INSTRUCTION_SET:armv5 = "arm"
|
|
|
|
EXTRA_OECMAKE = " \
|
|
-DWITH_PCAP=1 \
|
|
-DWITH_SFTP=1 \
|
|
-DWITH_ZLIB=1 \
|
|
-DLIB_SUFFIX=${@d.getVar('baselib').replace('lib', '')} \
|
|
"
|
|
|
|
do_configure:prepend () {
|
|
# Disable building of examples
|
|
sed -i -e '/add_subdirectory(examples)/s/^/#DONOTWANT/' ${S}/CMakeLists.txt \
|
|
|| bbfatal "Failed to disable examples"
|
|
}
|
|
|
|
do_compile:prepend () {
|
|
if [ ${PTEST_ENABLED} = "1" ]; then
|
|
sed -i -e 's|${B}|${PTEST_PATH}|g' ${B}/config.h
|
|
fi
|
|
}
|
|
|
|
do_install_ptest () {
|
|
install -d ${D}${PTEST_PATH}/tests
|
|
cp -f ${B}/tests/unittests/torture_* ${D}${PTEST_PATH}/tests/
|
|
}
|
|
|
|
TOOLCHAIN = "gcc"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|