mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-13 17:39:57 +00:00
Andreas Müller
cae9cafb9c
* Mixxx segfaulted during start. Remote debugging lead to function 'really_have_neon()'. * qtractor segfaulted when adding instruments as whysynth or hexter * seems autodetection fails in some other environments too [1]. * if TUNE_FEATURES contain 'neon' we can assume our machine supports NEON so we don't need runtime detection [1] https://github.com/FFTW/fftw3/issues/30 Signed-off-by: Andreas Müller <schnitzeltony@googlemail.com> Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
78 lines
2.0 KiB
BlitzBasic
78 lines
2.0 KiB
BlitzBasic
DESCRIPTION = "FFTW"
|
|
SECTION = "libs"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552"
|
|
|
|
SRC_URI = " \
|
|
http://www.fftw.org/fftw-${PV}.tar.gz \
|
|
file://0001-NEON-autodetection-segfaults-assume-neon-present.patch \
|
|
"
|
|
SRC_URI[md5sum] = "6cc08a3b9c7ee06fdd5b9eb02e06f569"
|
|
SRC_URI[sha256sum] = "8ecfe1b04732ec3f5b7d279fdb8efcad536d555f9d1e8fabd027037d45ea8bcf"
|
|
|
|
inherit autotools pkgconfig
|
|
|
|
# we had multiple recipes in the past
|
|
PROVIDES = "fftwl fftwf"
|
|
|
|
EXTRA_OECONF = "--disable-fortran --enable-shared --enable-threads"
|
|
|
|
FFTW_NEON = "${@bb.utils.contains('TUNE_FEATURES', 'neon', '--enable-neon', '', d)}"
|
|
FFTW_NEON_class-native = ""
|
|
|
|
do_configure() {
|
|
# configure fftw
|
|
rm -rf ${WORKDIR}/build-fftw
|
|
mkdir -p ${B}
|
|
cd ${B}
|
|
# full (re)configure
|
|
autotools_do_configure
|
|
mv ${B} ${WORKDIR}/build-fftw
|
|
|
|
# configure fftwl
|
|
rm -rf ${WORKDIR}/build-fftwl
|
|
mkdir -p ${B}
|
|
cd ${B}
|
|
# configure only
|
|
oe_runconf --enable-long-double
|
|
mv ${B} ${WORKDIR}/build-fftwl
|
|
|
|
# configure fftwf
|
|
rm -rf ${WORKDIR}/build-fftwf
|
|
mkdir -p ${B}
|
|
cd ${B}
|
|
# configure only
|
|
oe_runconf --enable-single ${FFTW_NEON}
|
|
mv ${B} ${WORKDIR}/build-fftwf
|
|
}
|
|
|
|
do_compile() {
|
|
for lib in fftw fftwl fftwf; do
|
|
cd ${WORKDIR}/build-$lib
|
|
autotools_do_compile
|
|
done
|
|
}
|
|
|
|
do_install() {
|
|
for lib in fftw fftwl fftwf; do
|
|
cd ${WORKDIR}/build-$lib
|
|
autotools_do_install
|
|
done
|
|
}
|
|
|
|
|
|
PACKAGES =+ "libfftw libfftwl libfftwf"
|
|
FILES_libfftw = "${libdir}/libfftw3.so.* ${libdir}/libfftw3_*.so.*"
|
|
FILES_libfftwl = "${libdir}/libfftw3l.so.* ${libdir}/libfftw3l_*.so.*"
|
|
FILES_libfftwf = "${libdir}/libfftw3f.so.* ${libdir}/libfftw3f_*.so.*"
|
|
|
|
PACKAGES =+ "fftw-wisdom fftwl-wisdom fftwf-wisdom fftw-wisdom-to-conf"
|
|
FILES_fftw-wisdom = "${bindir}/fftw-wisdom"
|
|
FILES_fftwl-wisdom = "${bindir}/fftwl-wisdom"
|
|
FILES_fftwf-wisdom = "${bindir}/fftwf-wisdom"
|
|
FILES_fftw-wisdom-to-conf = "${bindir}/fftw-wisdom-to-conf"
|
|
|
|
RDEPENDS_${PN}-dev = ""
|
|
|
|
BBCLASSEXTEND = "native"
|