mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-04-24 12:58:19 +00:00
cdb428e7c4
* based on discussion in pndeprecated thread: https://patchwork.openembedded.org/patch/137573/ update the messages to warn possible users that the recipe will be removed before the end of the next development cycle (before Yocto 2.4 is released). * updated with: sed -i 's/^\(PNBLACKLIST.*".*\)"/\1 - the recipe will be removed on 2017-09-01 unless the issue is fixed"/g' `git grep PNBLACKLIST | sed 's/:.*//g' | sort -u | xargs` * then noticed couple recipes being blacklisted only based on DISTRO_FEATURES, so removed those: meta-networking/recipes-support/lksctp-tools/lksctp-tools_1.0.17.bb meta-oe/recipes-connectivity/bluez/bluez-hcidump_2.5.bb meta-oe/recipes-connectivity/bluez/bluez4_4.101.bb meta-oe/recipes-connectivity/bluez/gst-plugin-bluetooth_4.101.bb meta-oe/recipes-navigation/foxtrotgps/foxtrotgps_1.1.1.bb meta-oe/recipes-navigation/gypsy/gypsy.inc meta-oe/recipes-navigation/navit/navit.inc meta-oe/recipes-support/opensync/libsyncml_0.5.4.bb * if it isn't fixed by this date, it's fair game to be removed whenever someone gets around to i Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
70 lines
2.8 KiB
PHP
70 lines
2.8 KiB
PHP
DESCRIPTION = "Webkit browser engine, EFL edition"
|
|
LICENSE = "GPLv2+ & LGPL-2.1"
|
|
LIC_FILES_CHKSUM = " \
|
|
file://Source/JavaScriptCore/COPYING.LIB;md5=d0c6d6397a5d84286dda758da57bd691 \
|
|
file://Source/WebCore/LICENSE-APPLE;md5=4646f90082c40bcf298c285f8bab0b12 \
|
|
file://Source/WebCore/LICENSE-LGPL-2.1;md5=a778a33ef338abbaf8b8a7c36b6eec80 \
|
|
file://Source/WebCore/LICENSE-LGPL-2;md5=36357ffde2b64ae177b2494445b79d21 \
|
|
"
|
|
|
|
# you need harfbuzz with icu enabled, you can add this to your config:
|
|
# PACKAGECONFIG_append_pn-harfbuzz = " icu"
|
|
DEPENDS = "icu libxslt sqlite3 gperf-native bison-native flex-native jpeg \
|
|
libpng libxt fontconfig cairo freetype glib-2.0 libsoup-2.4 \
|
|
libxml2 pango eina ecore evas edje eldbus harfbuzz enchant \
|
|
ruby-native elementary"
|
|
|
|
PE = "1"
|
|
|
|
SRCVER ?= "${PV}"
|
|
SRC_URI = "\
|
|
${E_RELEASES}/libs/webkit-efl/ewebkit-${SRCVER}.tar.xz \
|
|
"
|
|
S = "${WORKDIR}/ewebkit"
|
|
|
|
inherit cmake lib_package pkgconfig perlnative pythonnative
|
|
|
|
ARM_INSTRUCTION_SET = "arm"
|
|
|
|
EXTRA_OECMAKE = " \
|
|
-DPORT=Efl \
|
|
-DSHARED_CORE=On \
|
|
-DENABLE_DRAG_SUPPORT=On \
|
|
-DENABLE_WEB_AUDIO=Off \
|
|
-DENABLE_VIDEO=Off \
|
|
-DENABLE_VIDEO_TRACK=Off \
|
|
-DENABLE_ACCESSIBILITY=Off \
|
|
-DENABLE_BATTERY_STATUS=Off \
|
|
"
|
|
# generated ASM code isn't compatible with armv[45]
|
|
# it was removed from macro assembler in upstream commit 121885
|
|
# https://bugs.webkit.org/show_bug.cgi?id=90198
|
|
EXTRA_OECMAKE_append_armv4 = " -DENABLE_LLINT=Off -DENABLE_JIT=Off -DENABLE_DFG_JIT=Off -DENABLE_FTL_JIT=Off"
|
|
EXTRA_OECMAKE_append_armv5 = " -DENABLE_LLINT=Off -DENABLE_JIT=Off -DENABLE_DFG_JIT=Off -DENABLE_FTL_JIT=Off"
|
|
|
|
# hack it in OptionsEfl.cmake because that overrules -DENABLE_LLINT=Off
|
|
do_configure_prepend_armv4() {
|
|
sed -i 's/WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_LLINT ON)/WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_LLINT OFF)/g' ${S}/Source/cmake/OptionsEfl.cmake
|
|
}
|
|
do_configure_prepend_armv5() {
|
|
sed -i 's/WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_LLINT ON)/WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_LLINT OFF)/g' ${S}/Source/cmake/OptionsEfl.cmake
|
|
}
|
|
|
|
# and disabled LLINT currently isn't supported, so restrict to armv7a and x86*
|
|
COMPATIBLE_MACHINE = "(-)"
|
|
COMPATIBLE_MACHINE_x86 = "(.*)"
|
|
COMPATIBLE_MACHINE_x86-64 = "(.*)"
|
|
COMPATIBLE_MACHINE_armv7a = "(.*)"
|
|
|
|
LEAD_SONAME = "libewebkit.so"
|
|
PACKAGES =+ "${PN}launcher-dbg ${PN}launcher ${PN}-inspector"
|
|
|
|
FILES_${PN} += "${datadir}/ewebkit2-1/themes/default.edj"
|
|
FILES_${PN}-dev += "${libdir}/cmake"
|
|
FILES_${PN}launcher = "${bindir}/EWebLauncher"
|
|
FILES_${PN}launcher-dbg = "${bindir}/.debug/EWebLauncher"
|
|
FILES_${PN}-inspector += "${datadir}/ewebkit2-1/inspector"
|
|
|
|
# http://errors.yoctoproject.org/Errors/Details/40659/
|
|
PNBLACKLIST[webkit-efl] ?= "Old and unmaintaned fork with many security issues - the recipe will be removed on 2017-09-01 unless the issue is fixed"
|