mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-14 17:59:59 +00:00
Paul Eggleton
6c0509539b
A dependency on python-protobuf was added in commit
5f6fcfd362 for the sole purpose of
providing a ptest, however python-protobuf is in meta-python and thus
this means that meta-oe would depend on meta-python by default (assuming
your distro enables ptest by default), and we don't want that - meta-oe
isn't supposed to depend upon any layer other than openembedded-core.
Luckily we can still have a ptest even without the python support, so
add a PACKAGECONFIG and leave it disabled by default.
Note: the PACKAGECONFIG here is not particularly useful since it's only
about what goes into the -ptest package and thus also the dependency. I
contemplated just using LANG_SUPPORT instead, but PACKAGECONFIG does
have the advantage that it's introspectable and fairly well understood
so in the end I went with it.
Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
94 lines
3.0 KiB
BlitzBasic
94 lines
3.0 KiB
BlitzBasic
SUMMARY = "Protocol Buffers - structured data serialisation mechanism"
|
|
DESCRIPTION = "Protocol Buffers are a way of encoding structured data in an \
|
|
efficient yet extensible format. Google uses Protocol Buffers for almost \
|
|
all of its internal RPC protocols and file formats."
|
|
HOMEPAGE = "https://github.com/google/protobuf"
|
|
SECTION = "console/tools"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=37b5762e07f0af8c74ce80a8bda4266b"
|
|
|
|
DEPENDS = "zlib"
|
|
DEPENDS_append_class-target = " protobuf-native"
|
|
|
|
PV .= "+git${SRCPV}"
|
|
|
|
SRCREV = "48cb18e5c419ddd23d9badcfe4e9df7bde1979b2"
|
|
|
|
SRC_URI = "git://github.com/google/protobuf.git;branch=3.6.x \
|
|
file://run-ptest \
|
|
file://0001-protobuf-fix-configure-error.patch \
|
|
"
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools-brokensep pkgconfig ptest
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[python] = ",,"
|
|
|
|
EXTRA_OECONF += "--with-protoc=echo"
|
|
|
|
TEST_SRC_DIR = "examples"
|
|
LANG_SUPPORT = "cpp ${@bb.utils.contains('PACKAGECONFIG', 'python', 'python', '', d)}"
|
|
|
|
do_compile_ptest() {
|
|
# Modify makefile to use the cross-compiler
|
|
sed -e "s|c++|${CXX} \$(LDFLAGS)|g" -i "${S}/${TEST_SRC_DIR}/Makefile"
|
|
|
|
mkdir -p "${B}/${TEST_SRC_DIR}"
|
|
|
|
# Add the location of the cross-compiled header and library files
|
|
# which haven't been installed yet.
|
|
cp "${B}/protobuf.pc" "${B}/${TEST_SRC_DIR}/protobuf.pc"
|
|
sed -e 's|libdir=|libdir=${PKG_CONFIG_SYSROOT_DIR}|' -i "${B}/${TEST_SRC_DIR}/protobuf.pc"
|
|
sed -e 's|Cflags:|Cflags: -I${S}/src|' -i "${B}/${TEST_SRC_DIR}/protobuf.pc"
|
|
sed -e 's|Libs:|Libs: -L${B}/src/.libs|' -i "${B}/${TEST_SRC_DIR}/protobuf.pc"
|
|
export PKG_CONFIG_PATH="${B}/${TEST_SRC_DIR}"
|
|
|
|
# Save the pkgcfg sysroot variable, and update it to nothing so
|
|
# that it doesn't append the sysroot to the beginning of paths.
|
|
# The header and library files aren't installed to the target
|
|
# system yet. So the absolute paths were specified above.
|
|
save_pkg_config_sysroot_dir=$PKG_CONFIG_SYSROOT_DIR
|
|
export PKG_CONFIG_SYSROOT_DIR=
|
|
|
|
# Compile the tests
|
|
for lang in ${LANG_SUPPORT}; do
|
|
oe_runmake -C "${S}/${TEST_SRC_DIR}" ${lang}
|
|
done
|
|
|
|
# Restore the pkgconfig sysroot variable
|
|
export PKG_CONFIG_SYSROOT_DIR=$save_pkg_config_sysroot_dir
|
|
}
|
|
|
|
do_install_ptest() {
|
|
local olddir=`pwd`
|
|
|
|
cd "${S}/${TEST_SRC_DIR}"
|
|
install -d "${D}/${PTEST_PATH}"
|
|
for i in add_person* list_people*; do
|
|
if [ -x "$i" ]; then
|
|
install "$i" "${D}/${PTEST_PATH}"
|
|
fi
|
|
done
|
|
cp "${S}/${TEST_SRC_DIR}/addressbook_pb2.py" "${D}/${PTEST_PATH}"
|
|
cd "$olddir"
|
|
}
|
|
|
|
PACKAGE_BEFORE_PN = "${PN}-compiler ${PN}-lite"
|
|
|
|
FILES_${PN}-compiler = "${bindir} ${libdir}/libprotoc${SOLIBS}"
|
|
FILES_${PN}-lite = "${libdir}/libprotobuf-lite${SOLIBS}"
|
|
|
|
RDEPENDS_${PN}-compiler = "${PN}"
|
|
RDEPENDS_${PN}-dev += "${PN}-compiler"
|
|
RDEPENDS_${PN}-ptest = "bash ${@bb.utils.contains('PACKAGECONFIG', 'python', 'python-protobuf', '', d)}"
|
|
|
|
MIPS_INSTRUCTION_SET = "mips"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
LDFLAGS_append_arm = " -latomic"
|
|
LDFLAGS_append_mips = " -latomic"
|
|
LDFLAGS_append_powerpc = " -latomic"
|
|
LDFLAGS_append_mipsel = " -latomic"
|