mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-10-24 09:08:24 +00:00
Leon Anavi
9f6ae83d39
Upgrade to release 4.5.8: Bugs corrected: - Stdout: CSV data blocks use the first list item's fields instead of each item's own #3746 - Stdout: raw selector with a dotted item key (network.eth0.100.bytes_recv) raises UnboundLocalError #3748 - Folders: a second configured FolderList appends its entries to the first instance #3750 - JSON export: --stop-after leaves an empty file, the last sample is lost on shutdown #3752 - DuckDB export turns the string 'False' into TRUE #3754 - InfluxDB export truncates dotted list item identifiers (VLAN interfaces lose their tags) #3756 - IP plugin: a non-object public IP response raises AttributeError in the main thread #3758 - CSV export: rows are shifted under another device's column when the field order changes #3760 - Export: exporters mutate the live plugin statistics when merging limits #3766 - Elasticsearch export: a mapping type per plugin is rejected by ES 6/7/8+, only the first plugin is stored #3780 - Exports: an optional key missing from the config overwrote the module default with None #3781 - MQTT export: crash at startup when port or callback_api_version is omitted #3777 - Uptime: export the SNMP uptime instead of the local one #3779 - Cloud: do not report a platform whose metadata API returns nothing (OpenStack reported on Amazon EC2) #3778 - IRQ: divide the interrupt count by the refresh time (Rate/s was multiplied by the refresh time) #3771 - Programs: KeyError when a process stat is listed in [processlist] disable_stats #3776 - Containers: WebUI throws on a restarting container whose cpu/mem stats are empty #3768 - WebUI: the browser caches glances.js heuristically, revalidate the static files #3763 - Processes: io_old keeps one entry per pid ever seen (slow memory leak on hosts spawning short-lived processes) - Smart: a missing smartctl (pySMART >= 1.4) crashes the server at startup Enhancements: - WebUI: make the container table sortable by status #3763 - Processlist: only build curses rows for the processes that fit on screen (performance) #3762 Continuous integration and documentation: - Mark regression test assertions for Bandit Signed-off-by: Leon Anavi <leon.anavi@konsulko.com> Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
51 lines
1.7 KiB
BlitzBasic
51 lines
1.7 KiB
BlitzBasic
SUMMARY = "Glances is an open-source system cross-platform monitoring tool."
|
|
DESCRIPTION = "Glances an Eye on your system. A top/htop alternative for \
|
|
GNU/Linux, BSD, macOS and Windows operating systems."
|
|
HOMEPAGE = "https://nicolargo.github.io/glances/"
|
|
LICENSE = "LGPL-3.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=852ecadc0ac7e6f4d7144d5544a3815b"
|
|
|
|
SRC_URI[sha256sum] = "a1e5ed5a6488964a576d550a420c91af6f2c7c2d8df8e9fbe67c98eb38bacf3b"
|
|
|
|
inherit pypi python_setuptools_build_meta ptest-python-pytest
|
|
|
|
SRC_URI += " \
|
|
file://run-ptest \
|
|
git://github.com/nicolargo/glances.git;protocol=https;branch=master;name=testsdata;subpath=tests-data;destsuffix=glances-tests-data \
|
|
"
|
|
# tests-data/ is used by tests/test_core.py but not shipped in the pypi sdist,
|
|
# take it from the v4.5.6 tag
|
|
SRCREV_testsdata = "ce2f8506289c71e48ed8bf186f2c04d8256203d5"
|
|
|
|
# tests/test_core.py runs glances with ./conf/glances.conf and reads plugin
|
|
# test data from ./tests-data, both relative to the ptest directory
|
|
do_install_ptest:append() {
|
|
install -d ${D}${PTEST_PATH}/conf ${D}${PTEST_PATH}/tests-data
|
|
cp -rf ${S}/conf/* ${D}${PTEST_PATH}/conf/
|
|
cp -rf ${UNPACKDIR}/glances-tests-data/plugins ${D}${PTEST_PATH}/tests-data/
|
|
}
|
|
|
|
# psutil/jinja2/packaging are oe-core; fastapi/uvicorn/defusedxml are
|
|
# meta-python.
|
|
RDEPENDS:${PN} += " \
|
|
python3-psutil \
|
|
python3-packaging \
|
|
python3-defusedxml \
|
|
python3-fastapi \
|
|
python3-uvicorn \
|
|
python3-jinja2 \
|
|
python3-json \
|
|
python3-logging \
|
|
python3-asyncio \
|
|
python3-multiprocessing \
|
|
python3-netclient \
|
|
python3-xml \
|
|
"
|
|
|
|
RDEPENDS:${PN}-ptest += " \
|
|
python3-requests \
|
|
"
|
|
|
|
# Optional fast-JSON accelerator glances uses if present.
|
|
RRECOMMENDS:${PN} += "python3-orjson"
|