mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-14 17:59:59 +00:00
Hongzhi.Song
665235b74a
lib32-numactl has a error: root@intel-x86-64:~# numademo -t -e 1M Configured Nodes does not match available memory nodes That's because (long long int) is assigned to (long int). This will cause (long int) overflow on 32bit system. Unify variable types and fix it. Signed-off-by: Hongzhi.Song <hongzhi.song@windriver.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
61 lines
1.8 KiB
BlitzBasic
61 lines
1.8 KiB
BlitzBasic
SUMMARY = "Development package for building Applications that use numa"
|
|
HOMEPAGE = "http://oss.sgi.com/projects/libnuma/"
|
|
DESCRIPTION = "Simple NUMA policy support. It consists of a numactl program \
|
|
to run other programs with a specific NUMA policy and a libnuma to do \
|
|
allocations with NUMA policy in applications."
|
|
LICENSE = "GPL-2.0 & LGPL-2.1"
|
|
SECTION = "apps"
|
|
|
|
inherit autotools-brokensep ptest
|
|
|
|
LIC_FILES_CHKSUM = "file://README.md;beginline=19;endline=32;md5=f8ff2391624f28e481299f3f677b21bb"
|
|
|
|
SRCREV = "5d9f16722e3df49dc618a9f361bd482559695db7"
|
|
PV = "2.0.13+git${SRCPV}"
|
|
|
|
SRC_URI = "git://github.com/numactl/numactl \
|
|
file://Fix-the-test-output-format.patch \
|
|
file://Makefile \
|
|
file://run-ptest \
|
|
file://0001-define-run-test-target.patch \
|
|
file://0001-numademo-fix-error-on-32bit-system.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
# ARM does not currently support NUMA
|
|
COMPATIBLE_HOST = "^((?!arm).*)$"
|
|
|
|
do_install() {
|
|
oe_runmake DESTDIR=${D} prefix=${D}/usr install
|
|
#remove the empty man2 directory
|
|
rm -r ${D}${mandir}/man2
|
|
}
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake test
|
|
}
|
|
|
|
do_install_ptest() {
|
|
#install tests binaries
|
|
local test_binaries="distance ftok mbind_mig_pages migrate_pages move_pages \
|
|
mynode nodemap node-parse pagesize prefered randmap realloc_test \
|
|
tbitmap tshared"
|
|
|
|
[ ! -d ${D}/${PTEST_PATH}/test ] && mkdir -p ${D}/${PTEST_PATH}/test
|
|
for i in $test_binaries; do
|
|
install -m 0755 ${B}/test/.libs/$i ${D}${PTEST_PATH}/test
|
|
done
|
|
|
|
local test_scripts="checktopology checkaffinity printcpu regress regress2 \
|
|
shmtest runltp bind_range"
|
|
for i in $test_scripts; do
|
|
install -m 0755 ${B}/test/$i ${D}${PTEST_PATH}/test
|
|
done
|
|
|
|
install -m 0755 ${WORKDIR}/Makefile ${D}${PTEST_PATH}/
|
|
install -m 0755 ${B}/.libs/numactl ${D}${PTEST_PATH}/
|
|
}
|
|
|
|
RDEPENDS_${PN}-ptest = "bash"
|