Generalize the naming of the bootfiles deploy directory

The raspberry pi 4 variant has a BCM2711 chip, however it still
uses the same boot files as the BCM2835 used in previous generations.
This change generalizes the naming of the directory generated in the
$DEPLOY_DIR to avoid the implication that the files are only
meant for the BCM2835.

Signed-off-by: Jeff Ithier <ithijme@gmail.com>

recipes-bsp/bootfiles/bootfiles.bb

@@ -0,0 +1,43 @@
+DESCRIPTION = "Closed source binary files to help boot all raspberry pi devices."
+LICENSE = "Broadcom-RPi"
+
+LIC_FILES_CHKSUM = "file://LICENCE.broadcom;md5=c403841ff2837657b2ed8e5bb474ac8d"
+
+inherit deploy nopackages
+
+include recipes-bsp/common/raspberrypi-firmware.inc
+
+INHIBIT_DEFAULT_DEPS = "1"
+
+DEPENDS = "rpi-config"
+
+COMPATIBLE_MACHINE = "^rpi$"
+
+S = "${RPIFW_S}/boot"
+
+PR = "r3"
+
+do_deploy() {
+    install -d ${DEPLOYDIR}/${PN}
+
+    for i in ${S}/*.elf ; do
+        cp $i ${DEPLOYDIR}/${PN}
+    done
+    for i in ${S}/*.dat ; do
+        cp $i ${DEPLOYDIR}/${PN}
+    done
+    for i in ${S}/*.bin ; do
+        cp $i ${DEPLOYDIR}/${PN}
+    done
+
+    # Add stamp in deploy directory
+    touch ${DEPLOYDIR}/${PN}/${PN}-${PV}.stamp
+}
+
+do_deploy[depends] += "rpi-config:do_deploy"
+
+addtask deploy before do_build after do_install
+do_deploy[dirs] += "${DEPLOYDIR}/${PN}"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+