mirror of
https://github.com/jiazhang0/meta-secure-core.git
synced 2026-05-06 09:48:40 +00:00
fea6a37625
Update SRC_URIs using git to include branch=master if no branch is set and also to use protocol=https for github urls. Signed-off-by: Yi Zhao <yi.zhao@windriver.com>
120 lines
3.8 KiB
BlitzBasic
120 lines
3.8 KiB
BlitzBasic
SUMMARY = "TrouSerS - An open-source TCG Software Stack implementation."
|
|
DESCRIPTION = "\
|
|
Trousers is an open-source TCG Software Stack (TSS), released under the \
|
|
Common Public License. Trousers aims to be compliant with the current (1.1b) \
|
|
and upcoming (1.2) TSS specifications available from the Trusted Computing \
|
|
Group website: http://www.trustedcomputinggroup.org. \
|
|
"
|
|
HOMEPAGE = "https://sourceforge.net/projects/trousers"
|
|
SECTION = "security/tpm"
|
|
|
|
LICENSE = "BSD"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=8031b2ae48ededc9b982c08620573426"
|
|
|
|
DEPENDS = "openssl"
|
|
PROVIDES = "${PACKAGES}"
|
|
|
|
PV = "0.3.14+git${SRCPV}"
|
|
|
|
SRC_URI = "\
|
|
git://git.code.sf.net/p/trousers/trousers;branch=master \
|
|
file://fix-deadlock-and-potential-hung.patch \
|
|
file://fix-event-log-parsing-problem.patch \
|
|
file://fix-incorrect-report-of-insufficient-buffer.patch \
|
|
file://trousers-conditional-compile-DES-related-code.patch \
|
|
file://Fix-segment-fault-if-client-hostname-cannot-be-retri.patch \
|
|
file://get-user-ps-path-use-POSIX-getpwent-instead-of-getpwe.patch \
|
|
file://trousers.init.sh \
|
|
file://trousers-udev.rules \
|
|
file://tcsd.service \
|
|
file://tcsd.conf \
|
|
"
|
|
SRCREV = "e74dd1d96753b0538192143adf58d04fcd3b242b"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools pkgconfig useradd update-rc.d \
|
|
${@bb.utils.contains('VIRTUAL-RUNTIME_init_manager', 'systemd', 'systemd', '', d)}
|
|
|
|
EXTRA_OECONF="--with-gui=none"
|
|
|
|
# Fix build failure for gcc-10
|
|
CFLAGS:append = " -fcommon"
|
|
|
|
PACKAGECONFIG ?= "gmp "
|
|
PACKAGECONFIG[gmp] = "--with-gmp, --with-gmp=no, gmp"
|
|
PACKAGECONFIG[gtk] = "--with-gui=gtk, --with-gui=none, gtk+"
|
|
|
|
INITSCRIPT_NAME = "trousers"
|
|
INITSCRIPT_PARAMS = "start 99 2 3 4 5 . stop 19 0 1 6 ."
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
GROUPADD_PARAM:${PN} = "--system tss"
|
|
USERADD_PARAM:${PN} = "--system -M -d /var/lib/tpm -s /bin/false -g tss tss"
|
|
|
|
SYSTEMD_PACKAGES = "${PN}"
|
|
SYSTEMD_SERVICE:${PN} = "tcsd.service"
|
|
SYSTEMD_AUTO_ENABLE = "enable"
|
|
|
|
do_install:append() {
|
|
install -d "${D}${sysconfdir}/init.d"
|
|
install -m 0755 "${WORKDIR}/trousers.init.sh" "${D}${sysconfdir}/init.d/trousers"
|
|
|
|
install -m 0600 "${WORKDIR}/tcsd.conf" "${D}${sysconfdir}"
|
|
chown tss:tss "${D}${sysconfdir}/tcsd.conf"
|
|
|
|
install -d "${D}${sysconfdir}/udev/rules.d"
|
|
install -m 0644 "${WORKDIR}/trousers-udev.rules" \
|
|
"${D}${sysconfdir}/udev/rules.d/45-trousers.rules"
|
|
|
|
if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
|
|
install -d "${D}${systemd_unitdir}/system"
|
|
install -m 0644 "${WORKDIR}/tcsd.service" "${D}${systemd_unitdir}/system"
|
|
sed -i -e 's#@SBINDIR@#${sbindir}#g' ${D}${systemd_unitdir}/system/tcsd.service
|
|
fi
|
|
}
|
|
|
|
PACKAGES =+ "\
|
|
libtspi \
|
|
libtspi-dbg \
|
|
libtspi-dev \
|
|
libtspi-doc \
|
|
libtspi-staticdev \
|
|
"
|
|
|
|
FILES:libtspi = "\
|
|
${libdir}/libtspi.so.* \
|
|
"
|
|
FILES:libtspi-dbg = "\
|
|
${libdir}/.debug \
|
|
${prefix}/src/debug/${PN}/${PV}-${PR}/${PN}-${PV}/src/tspi \
|
|
${prefix}/src/debug/${PN}/${PV}-${PR}/${PN}-${PV}/src/trspi \
|
|
${prefix}/src/debug/${PN}/${PV}-${PR}/${PN}-${PV}/src/include/*.h \
|
|
${prefix}/src/debug/${PN}/${PV}-${PR}/${PN}-${PV}/src/include/tss \
|
|
"
|
|
FILES:libtspi-dev = "\
|
|
${includedir} \
|
|
${libdir}/*.so \
|
|
"
|
|
FILES:libtspi-doc = "\
|
|
${mandir}/man3 \
|
|
"
|
|
FILES:libtspi-staticdev = "\
|
|
${libdir}/*.la \
|
|
${libdir}/*.a \
|
|
"
|
|
FILES:${PN}-dbg += "\
|
|
${sbindir}/.debug \
|
|
${prefix}/src/debug/${PN}/${PV}-${PR}/${PN}-${PV}/src/tcs \
|
|
${prefix}/src/debug/${PN}/${PV}-${PR}/${PN}-${PV}/src/tcsd \
|
|
${prefix}/src/debug/${PN}/${PV}-${PR}/${PN}-${PV}/src/tddl \
|
|
${prefix}/src/debug/${PN}/${PV}-${PR}/${PN}-${PV}/src/trousers \
|
|
${prefix}/src/debug/${PN}/${PV}-${PR}/${PN}-${PV}/src/include/trousers \
|
|
"
|
|
FILES:${PN}-dev += "${libdir}/trousers"
|
|
FILES:${PN} += "${systemd_unitdir}/system/tcsd.service"
|
|
|
|
CONFFILES:${PN} += "${sysconfig}/tcsd.conf"
|
|
|
|
BBCLASSEXTEND = "native"
|