mirror of
https://git.yoctoproject.org/meta-security
synced 2026-10-20 18:58:39 +00:00
Scott Murray
494a4a0d85
Upgrade to 0.16.0, and add a patch to refresh Cargo.lock to pick up openssl-sys >= 0.9.114, which adds OpenSSL 4.0 support. Release notes: https://github.com/NLnetLabs/krill/releases/tag/v0.13.0 https://github.com/NLnetLabs/krill/releases/tag/v0.13.1 https://github.com/NLnetLabs/krill/releases/tag/v0.14.0 https://github.com/NLnetLabs/krill/releases/tag/v0.14.1 https://github.com/NLnetLabs/krill/releases/tag/v0.14.2 https://github.com/NLnetLabs/krill/releases/tag/v0.14.3 https://github.com/NLnetLabs/krill/releases/tag/v0.14.4 https://github.com/NLnetLabs/krill/releases/tag/v0.14.5 https://github.com/NLnetLabs/krill/releases/tag/v0.14.6 https://github.com/NLnetLabs/krill/releases/tag/v0.15.0 https://github.com/NLnetLabs/krill/releases/tag/v0.15.1 https://github.com/NLnetLabs/krill/releases/tag/v0.16.0 Signed-off-by: Scott Murray <scott.murray@konsulko.com>
45 lines
1.4 KiB
BlitzBasic
45 lines
1.4 KiB
BlitzBasic
SUMMARY = "Resource Public Key Infrastructure (RPKI) daemon"
|
|
HOMEPAGE = "https://www.nlnetlabs.nl/projects/rpki/krill/"
|
|
LICENSE = "MPL-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=9741c346eef56131163e13b9db1241b3"
|
|
|
|
DEPENDS = "openssl"
|
|
|
|
SRC_URI = "git://github.com/NLnetLabs/krill.git;protocol=https;branch=main \
|
|
file://0001-Disable-abort-on-panic.patch \
|
|
file://0002-Update-crate-dependencies.patch \
|
|
"
|
|
SRCREV = "b2a26cd9f44a385d8a62a0199b082f44e5062039"
|
|
|
|
include krill-crates.inc
|
|
|
|
UPSTREAM_CHECK_URI = "https://github.com/NLnetLabs/${BPN}/releases"
|
|
UPSTREAM_CHECK_GITTAGREGEX = "v(?P<pver>\d+(\.\d+)+)"
|
|
|
|
CARGO_SRC_DIR = ""
|
|
|
|
inherit pkgconfig useradd systemd cargo cargo-update-recipe-crates
|
|
|
|
do_install:append () {
|
|
install -d ${D}${sysconfdir}
|
|
install -d ${D}${datadir}/krill
|
|
|
|
install -m 664 ${S}/defaults/krill.conf ${D}${sysconfdir}/.
|
|
install ${S}/defaults/* ${D}${datadir}/krill/.
|
|
find ${D}${bindir}/ -name "krill*" -exec sed -i -e 's#${CARGO_HOME}/bitbake##g' {} +
|
|
}
|
|
|
|
KRILL_UID ?= "krill"
|
|
KRILL_GID ?= "krill"
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
GROUPADD_PARAM:${PN} = "--system ${KRILL_UID}"
|
|
USERADD_PARAM:${PN} = "--system -g ${KRILL_GID} --home-dir \
|
|
/var/lib/krill/ --no-create-home \
|
|
--shell /sbin/nologin ${BPN}"
|
|
|
|
FILES:${PN} += "${sysconfdir}/defaults ${datadir}"
|
|
INSANE_SKIP:${PN} = "already-stripped"
|
|
|
|
COMPATIBLE_HOST = "(i.86|x86_64|aarch64).*-linux"
|