mirror of
https://git.yoctoproject.org/meta-security
synced 2026-04-20 11:29:37 +00:00
30a5e16b75
Fixes: error in fail2ban setup command: use_2to3 is invalid. ERROR: 'python3 setup.py build ' execution failed. drop custom fail2ban_setup.py remove pyhton-fail2ban as its a symlink to python3 Update to tip for 11.2 branch Signed-off-by: Armin Kuster <akuster808@gmail.com>
54 lines
1.9 KiB
BlitzBasic
54 lines
1.9 KiB
BlitzBasic
SUMMARY = "Daemon to ban hosts that cause multiple authentication errors."
|
|
DESCRIPTION = "Fail2Ban scans log files like /var/log/auth.log and bans IP addresses having too \
|
|
many failed login attempts. It does this by updating system firewall rules to reject new \
|
|
connections from those IP addresses, for a configurable amount of time. Fail2Ban comes \
|
|
out-of-the-box ready to read many standard log files, such as those for sshd and Apache, \
|
|
and is easy to configure to read any log file you choose, for any error you choose."
|
|
HOMEPAGE = "http://www.fail2ban.org"
|
|
|
|
LICENSE = "GPL-2.0"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=ecabc31e90311da843753ba772885d9f"
|
|
|
|
SRCREV ="d6b884f3b72b8a42b21da863836569ef6836c2ea"
|
|
SRC_URI = " git://github.com/fail2ban/fail2ban.git;branch=0.11 \
|
|
file://initd \
|
|
file://run-ptest \
|
|
"
|
|
|
|
inherit update-rc.d ptest setuptools3
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
do_compile () {
|
|
cd ${S}
|
|
./fail2ban-2to3
|
|
}
|
|
|
|
do_install:append () {
|
|
rm -f ${D}/${bindir}/fail2ban-python
|
|
install -d ${D}/${sysconfdir}/fail2ban
|
|
install -d ${D}/${sysconfdir}/init.d
|
|
install -m 0755 ${WORKDIR}/initd ${D}${sysconfdir}/init.d/fail2ban-server
|
|
chown -R root:root ${D}/${bindir}
|
|
}
|
|
|
|
do_install_ptest:append () {
|
|
install -d ${D}${PTEST_PATH}
|
|
install -d ${D}${PTEST_PATH}/bin
|
|
sed -i -e 's/##PYTHON##/${PYTHON_PN}/g' ${D}${PTEST_PATH}/run-ptest
|
|
install -D ${S}/bin/* ${D}${PTEST_PATH}/bin
|
|
rm -f ${D}${PTEST_PATH}/bin/fail2ban-python
|
|
}
|
|
|
|
FILES:${PN} += "/run"
|
|
|
|
INITSCRIPT_PACKAGES = "${PN}"
|
|
INITSCRIPT_NAME = "fail2ban-server"
|
|
INITSCRIPT_PARAMS = "defaults 25"
|
|
|
|
INSANE_SKIP:${PN}:append = "already-stripped"
|
|
|
|
RDEPENDS:${PN} = "${VIRTUAL-RUNTIME_base-utils-syslog} iptables sqlite3 python3-core python3-pyinotify"
|
|
RDEPENDS:${PN} += " python3-logging python3-fcntl python3-json"
|
|
RDEPENDS:${PN}-ptest = "python3-core python3-io python3-modules python3-fail2ban"
|