mirror of
https://git.yoctoproject.org/meta-security
synced 2026-01-11 15:00:34 +00:00
4e2b318a86
v2 : also fix some typos while we are here. v3 : add fixes for isic and checksecurity Signed-off-by: Jason Schonberg <schonm@gmail.com> [removed already applied change] Signed-off-by: Scott Murray <scott.murray@konsulko.com>
78 lines
3.0 KiB
BlitzBasic
78 lines
3.0 KiB
BlitzBasic
SUMMARY = "Tripwire: A system integrity assessment tool (IDS)"
|
|
DESCRIPTION = "Open Source Tripwire® software is a security and data \
|
|
integrity tool useful for monitoring and alerting on specific file change(s) on a range of systems"
|
|
HOMEPAGE = "http://sourceforge.net/projects/tripwire"
|
|
SECTION = "security Monitor/Admin"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=1c069be8dbbe48e89b580ab4ed86c127"
|
|
|
|
SRCREV = "6e64a9e5b70a909ec439bc5a099e3fcf38c614b0"
|
|
|
|
SRC_URI = "\
|
|
git://github.com/Tripwire/tripwire-open-source.git;branch=master;protocol=https \
|
|
file://tripwire.cron \
|
|
file://tripwire.sh \
|
|
file://tripwire.txt \
|
|
file://twcfg.txt \
|
|
file://twinstall.sh \
|
|
file://twpol-yocto.txt \
|
|
file://run-ptest \
|
|
"
|
|
|
|
S = "${UNPACKDIR}/git"
|
|
|
|
inherit autotools-brokensep update-rc.d ptest
|
|
|
|
INITSCRIPT_NAME = "tripwire"
|
|
INITSCRIPT_PARAMS = "start 40 S ."
|
|
TRIPWIRE_HOST = "${HOST_SYS}"
|
|
TRIPWIRE_TARGET = "${TARGET_SYS}"
|
|
|
|
CXXFLAGS += "-fno-strict-aliasing"
|
|
EXTRA_OECONF = "--disable-openssl --enable-static --sysconfdir=/etc/tripwire"
|
|
|
|
do_install () {
|
|
install -d ${D}${libdir} ${D}${datadir} ${D}${base_libdir}
|
|
install -d ${D}${sysconfdir} ${D}${mandir} ${D}${sbindir}
|
|
install -d ${D}${sysconfdir}/${PN}
|
|
install -d ${D}${localstatedir}/lib/${PN} ${D}${localstatedir}/lib/${BPN}/report
|
|
install -d ${D}${mandir}/man4 ${D}${mandir}/man5 ${D}${mandir}/man8
|
|
install -d ${D}${docdir}/${BPN} ${D}${docdir}/${BPN}/templates
|
|
install -d ${D}${sysconfdir}/init.d
|
|
|
|
install -m 0755 ${S}/bin/* ${D}${sbindir}
|
|
install -m 0644 ${S}/lib/* ${D}${base_libdir}
|
|
install -m 0644 ${S}/lib/* ${D}${localstatedir}/lib/${PN}
|
|
install -m 0755 ${UNPACKDIR}/tripwire.cron ${D}${sysconfdir}
|
|
install -m 0755 ${UNPACKDIR}/tripwire.sh ${D}${sysconfdir}/init.d/tripwire
|
|
install -m 0755 ${UNPACKDIR}/twinstall.sh ${D}${sysconfdir}/${PN}
|
|
install -m 0644 ${UNPACKDIR}/twpol-yocto.txt ${D}${sysconfdir}/${PN}/twpol.txt
|
|
install -m 0644 ${UNPACKDIR}/twcfg.txt ${D}${sysconfdir}/${PN}
|
|
|
|
install -m 0644 ${S}/man/man4/* ${D}${mandir}/man4
|
|
install -m 0644 ${S}/man/man5/* ${D}${mandir}/man5
|
|
install -m 0644 ${S}/man/man8/* ${D}${mandir}/man8
|
|
rm ${D}${mandir}/man*/Makefile*
|
|
install -m 0644 ${S}/policy/templates/* ${D}${docdir}/${BPN}/templates
|
|
install -m 0644 ${S}/policy/*txt ${D}${docdir}/${BPN}
|
|
install -m 0644 ${S}/COPYING ${D}${docdir}/${BPN}
|
|
install -m 0644 ${S}/TRADEMARK ${D}${docdir}/${BPN}
|
|
install -m 0644 ${UNPACKDIR}/tripwire.txt ${D}${docdir}/${BPN}
|
|
}
|
|
|
|
do_install_ptest:append () {
|
|
install -d ${D}${PTEST_PATH}/tests
|
|
cp -a ${S}/src/test-harness/* ${D}${PTEST_PATH}
|
|
sed -i -e 's@../../../../bin@${sbindir}@' ${D}${PTEST_PATH}/twtools.pm
|
|
}
|
|
|
|
FILES:${PN} += "${libdir} ${docdir}/${PN}/*"
|
|
FILES:${PN}-dbg += "${sysconfdir}/${PN}/.debug"
|
|
FILES:${PN}-staticdev += "${localstatedir}/lib/${PN}/lib*.a"
|
|
FILES:${PN}-ptest += "${PTEST_PATH}/tests "
|
|
|
|
RDEPENDS:${PN} += " perl nano msmtp cronie"
|
|
RDEPENDS:${PN}-ptest = " perl lib-perl perl-modules "
|
|
|
|
SKIP_RECIPE[tripwire] ?= "Upsteram project appears to be abondoned, fails to build with gcc11"
|