From 0e3d63eb9f1c8cce6228eb424eea1aa2aa835cb9 Mon Sep 17 00:00:00 2001
From: Sam Nelson <sam.nelson@ti.com>
Date: Thu, 6 Nov 2014 04:17:04 +0000
Subject: [PATCH] hyplnk-lld: Add new recipe for Hyperlink lld

- Provides low level driver for Hyperlink module
- Test recipe is used to build tests and examples using
  the hyperlink library.
- Supports k2h, k2k & k2e

Signed-off-by: Sam Nelson <sam.nelson@ti.com>
Signed-off-by: Denys Dmytriyenko <denys@ti.com>
---
 recipes-bsp/hyplnk-lld/hyplnk-lld-test_git.bb | 32 +++++++++++++++++++
 recipes-bsp/hyplnk-lld/hyplnk-lld.inc         | 24 ++++++++++++++
 recipes-bsp/hyplnk-lld/hyplnk-lld_git.bb      | 22 +++++++++++++
 3 files changed, 78 insertions(+)
 create mode 100755 recipes-bsp/hyplnk-lld/hyplnk-lld-test_git.bb
 create mode 100644 recipes-bsp/hyplnk-lld/hyplnk-lld.inc
 create mode 100755 recipes-bsp/hyplnk-lld/hyplnk-lld_git.bb

diff --git a/recipes-bsp/hyplnk-lld/hyplnk-lld-test_git.bb b/recipes-bsp/hyplnk-lld/hyplnk-lld-test_git.bb
new file mode 100755
index 00000000..8212c971
--- /dev/null
+++ b/recipes-bsp/hyplnk-lld/hyplnk-lld-test_git.bb
@@ -0,0 +1,32 @@
+include hyplnk-lld.inc
+
+DEPENDS = "common-csl-ip hyplnk-lld"
+
+CHOICELIST = " yes \
+               no  \
+"
+
+do_compile () {
+	make -f makefile_armv7 clean PDK_INSTALL_PATH="${STAGING_INCDIR}" \
+		HYPLNK_SRC_DIR="${S}"
+	for device in ${DEVICELIST}
+	do
+		for choice in ${CHOICELIST}
+		do
+			make -f makefile_armv7 tests examples \
+				PDK_INSTALL_PATH="${STAGING_INCDIR}" \
+				DEVICE="$device" HYPLNK_SRC_DIR="${S}" \
+				USEDYNAMIC_LIB="$choice"
+		done
+	done
+}
+
+do_install () {
+    for device in ${DEVICELIST}
+	do
+		make -f makefile_armv7 installbin \
+			PDK_INSTALL_PATH="${STAGING_INCDIR}" DEVICE="$device" \
+			HYPLNK_SRC_DIR="${S}" \
+			INSTALL_BIN_BASE_DIR="${D}/${bindir}"
+	done
+}
diff --git a/recipes-bsp/hyplnk-lld/hyplnk-lld.inc b/recipes-bsp/hyplnk-lld/hyplnk-lld.inc
new file mode 100644
index 00000000..4c8bb32a
--- /dev/null
+++ b/recipes-bsp/hyplnk-lld/hyplnk-lld.inc
@@ -0,0 +1,24 @@
+DESCRIPTION = "TI Hyperlink Low Level Driver"
+LICENSE = "BSD-3-Clause"
+
+COMPATIBLE_MACHINE = "keystone"
+
+LLDNAME="hyplnk"
+
+LIC_FILES_CHKSUM = "file://${WORKDIR}/git/ti/drv/${LLDNAME}/COPYING.txt;md5=623325cc19e613a4e770fbb749922592"
+
+BRANCH="master"
+SRC_URI = "git://git.ti.com/keystone-rtos/hyplnk-lld.git;destsuffix=git/ti/drv/${LLDNAME};protocol=git;branch=${BRANCH}"
+# Following commit corresponds to tag DEV.HYPLNK_LLD.02.01.00.01
+SRCREV = "6910da379501984ecf27f8d23ba6fc6310fe387e"
+
+PV = "2.1.0"
+PR = "r0"
+
+DEVICELIST = " k2h \
+               k2k \
+               k2e \
+"
+
+BASEDIR = "${WORKDIR}/git"
+S = "${BASEDIR}/ti/drv/${LLDNAME}"
diff --git a/recipes-bsp/hyplnk-lld/hyplnk-lld_git.bb b/recipes-bsp/hyplnk-lld/hyplnk-lld_git.bb
new file mode 100755
index 00000000..a582f981
--- /dev/null
+++ b/recipes-bsp/hyplnk-lld/hyplnk-lld_git.bb
@@ -0,0 +1,22 @@
+include hyplnk-lld.inc
+
+DEPENDS = "common-csl-ip"
+
+CHOICELIST = " yes \
+               no  \
+"
+do_compile () {
+	make -f makefile_armv7 clean PDK_INSTALL_PATH="${STAGING_INCDIR}" \
+		HYPLNK_SRC_DIR="${S}"
+	for device in ${DEVICELIST}
+	do
+		make -f makefile_armv7 lib PDK_INSTALL_PATH="${STAGING_INCDIR}"\
+			DEVICE="$device" HYPLNK_SRC_DIR="${S}"
+	done
+}
+
+do_install () {
+	make -f makefile_armv7 install PDK_INSTALL_PATH="${STAGING_INCDIR}" \
+		INSTALL_INC_BASE_DIR="${D}/${includedir}" \
+		INSTALL_LIB_BASE_DIR="${D}${libdir}" HYPLNK_SRC_DIR="${S}"
+}