ti-hsm-demo-fw: Add a recipe to export prebuilt HSM demo firmware

Add a recipe to deploy the HSM demo firmware to the DEPLOYDIR, to be
picked up by the tisdk-core-bundle for the prebuilt binaries directory.
This firmware is then further picked by U-Boot and packaged inside
tispl.bin FIT image for loading the HSM M4 core in applicable SoCs.

Signed-off-by: Beleswar Padhi <b-padhi@ti.com>
Signed-off-by: Ryan Eatmon <reatmon@ti.com>

meta-ti-bsp/recipes-bsp/ti-hsm-fw/ti-hsm-demo-fw_git.bb

@@ -0,0 +1,24 @@
+SUMMARY = "TI HSM demo Firmware"
+
+inherit deploy
+
+require recipes-bsp/ti-linux-fw/ti-linux-fw.inc
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+PV = "${TI_HSM_DEMO_FW_VERSION}"
+PR = "${INC_PR}.0"
+
+COMPATIBLE_MACHINE = "j721s2|j784s4"
+
+HSM_FW_SOC:j721s2 = "j721s2"
+HSM_FW_SOC:j784s4 = "j784s4"
+
+HSM_BINARY = "hsm-demo-firmware-${HSM_FW_SOC}*.bin"
+
+do_deploy() {
+	install -d ${DEPLOYDIR}/ti-hsm
+	install -m 644 ${S}/ti-hsm/${HSM_BINARY} ${DEPLOYDIR}/ti-hsm
+}
+
+addtask deploy before do_build after do_compile

meta-ti-bsp/recipes-bsp/ti-linux-fw/ti-linux-fw.inc

@@ -16,6 +16,7 @@ IMG_DEC_FW_VERSION = "1.0"
 CNM_WAVE521_FW_VERSION = "1.0.7"
 TI_DM_FW_VERSION = "11.00.09"
 TI_SYSFW_VERSION = "11.00.07"
+TI_HSM_DEMO_FW_VERSION = "11.00.09"
 
 TI_LINUX_FW_SRCREV ?= "c3ad8113c766bee7b8ddfae222e9b8017b565ea3"
 SRCREV = "${TI_LINUX_FW_SRCREV}"

meta-ti-bsp/recipes-bsp/u-boot/u-boot-ti.inc

@@ -40,6 +40,10 @@ DEPENDS += "python3-pyelftools-native python3-pyyaml-native python3-jsonschema-n
 DEPENDS:append:k3 = " ti-sci-fw"
 DEPENDS:append:k3r5 = " ti-sci-fw"
 
+# HSM Demo Firmware is only applicable for J721S2 & J784S4 devices
+DEPENDS:append:j721s2 = " ti-hsm-demo-fw"
+DEPENDS:append:j784s4 = " ti-hsm-demo-fw"
+
 DM_FIRMWARE = "ipc_echo_testb_mcu1_0_release_strip.xer5f"
 
 PLAT_SFX = ""