mirror of
https://git.yoctoproject.org/meta-ti
synced 2026-04-20 19:53:43 +00:00
7136eed3f5
The ipumm-fw repository had to undergo a forced commit update. This was an unforeseen update and had to be done in urgency. This recipe update takes care of fixing the new commit-id that corresponds to the previous version that was being used. There is no functional change. Signed-off-by: Karthik Ramanan <a0393906@ti.com> Signed-off-by: Denys Dmytriyenko <denys@ti.com>
70 lines
2.0 KiB
BlitzBasic
70 lines
2.0 KiB
BlitzBasic
python __anonymous() {
|
|
features = bb.data.getVar("MACHINE_FEATURES", d, 1)
|
|
if not features:
|
|
return
|
|
if "mmip" not in features:
|
|
raise bb.parse.SkipPackage('ipumm-fw does not apply to systems without the "mmip" flag in MACHINE_FEATURES')
|
|
}
|
|
|
|
DESCRIPTION = "Firmware for IPU for supporting Accelerated MM decode and encode"
|
|
LICENSE = "TI-TSPA"
|
|
|
|
LIC_FILES_CHKSUM = "file://Texas_Instruments_ipumm_Manifest.pdf;md5=5cc572579f07af266ab57fc17d762c7f"
|
|
|
|
COMPATIBLE_MACHINE = "dra7xx"
|
|
|
|
RDEPENDS_${PN} = " libdce"
|
|
|
|
SRC_URI = "git://git.ti.com/ivimm/ipumm.git;protocol=git"
|
|
|
|
SRCREV = "2aa80581cc7d1d82a1af9a46c37793b2fe8b9d42"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
PV = "3.00.13.00"
|
|
PR = "r6"
|
|
|
|
require recipes-ti/includes/ti-paths.inc
|
|
|
|
inherit update-alternatives
|
|
|
|
DEPENDS = "ti-xdctools ti-sysbios ti-codec-engine ti-framework-components ti-xdais ti-cgt-arm-native ti-ipc-rtos"
|
|
|
|
export HWVERSION="ES10"
|
|
export BIOSTOOLSROOT="${STAGING_DIR_TARGET}/usr/share/ti"
|
|
|
|
export XDCVERSION="ti-xdctools-tree"
|
|
export BIOSVERSION="ti-sysbios-tree"
|
|
export IPCVERSION="ti-ipc-tree"
|
|
export CEVERSION="ti-codec-engine-tree"
|
|
export FCVERSION="ti-framework-components-tree"
|
|
export XDAISVERSION="ti-xdais-tree"
|
|
|
|
export TMS470CGTOOLPATH="${M4_TOOLCHAIN_INSTALL_DIR}"
|
|
export IPCSRC="${STAGING_DIR_TARGET}/usr/share/ti/ti-ipc-tree"
|
|
|
|
do_configure() {
|
|
oe_runmake unconfig
|
|
oe_runmake vayu_smp_config
|
|
}
|
|
|
|
do_compile() {
|
|
oe_runmake
|
|
}
|
|
|
|
TARGET = "dra7-ipu2-fw.xem4"
|
|
TARGET_MAP = "platform/ti/dce/baseimage/package/cfg/out/ipu/release/ipu.xem4.map"
|
|
|
|
do_install() {
|
|
install -d ${D}${base_libdir}/firmware
|
|
install -m 0644 ${S}/${TARGET} ${D}${base_libdir}/firmware/${TARGET}.${BPN}
|
|
install -m 0644 ${S}/${TARGET_MAP} ${D}${base_libdir}/firmware/${TARGET}.map
|
|
}
|
|
|
|
ALTERNATIVE_${PN} = "dra7-ipu2-fw.xem4"
|
|
ALTERNATIVE_LINK_NAME[dra7-ipu2-fw.xem4] = "${base_libdir}/firmware/${TARGET}"
|
|
ALTERNATIVE_TARGET[dra7-ipu2-fw.xem4] = "${base_libdir}/firmware/${TARGET}.${BPN}"
|
|
ALTERNATIVE_PRIORITY = "20"
|
|
|
|
FILES_${PN} += "${base_libdir}/firmware/*"
|