mirror of
https://git.yoctoproject.org/meta-ti
synced 2026-05-07 11:59:49 +00:00
Jacob Stiffler
d1ad0605c4
Recently individual components and LLD sources have been combined into a single PDK repo. Use this class to specify the common source. Also use this class to keep the sources separate from each other when building. This keeps the build identical to previous recipes while keeping control on interdependencies. Similar to gcc-source, use the ti-pdk-source recipe to unpack the sources into a "work-shared" area. Then hard-link only the necessary files into a recipe's WORKDIR. Signed-off-by: Jacob Stiffler <j-stiffler@ti.com> Signed-off-by: Denys Dmytriyenko <denys@ti.com>
44 lines
1.3 KiB
Plaintext
44 lines
1.3 KiB
Plaintext
TI_PDK_GIT_URI ?= "git://git.ti.com/processor-sdk/pdk.git"
|
|
TI_PDK_GIT_BRANCH ?= "master"
|
|
TI_PDK_GIT_PROTOCOL ?= "git"
|
|
TI_PDK_SRCREV ?= "69b8b56273fe0c9085fb92d9bfcb7367b724c8af"
|
|
|
|
TI_PDK_VERSION ?= "2019.11.0"
|
|
|
|
PV = "${TI_PDK_VERSION}"
|
|
|
|
TI_PDK_COMP ?= ""
|
|
TI_PDK_COMP_PATH = "${@'${TI_PDK_COMP}'.replace('.','/')}"
|
|
|
|
TI_PDK_SOURCE_PN = "ti-pdk-source"
|
|
TI_PDK_SOURCE_WORKDIR = "${TMPDIR}/work-shared/ti-pdk-${PV}"
|
|
TI_PDK_SOURCE = "${TI_PDK_SOURCE_WORKDIR}/git"
|
|
|
|
S = "${WORKDIR}/git/${TI_PDK_COMP_PATH}"
|
|
|
|
# Hard-link only required sources from PDK
|
|
python do_unpack_append() {
|
|
if len(d.getVar('TI_PDK_COMP') or '') > 0:
|
|
import shutil
|
|
|
|
# Get src/dst paths
|
|
src = os.path.join(d.getVar('TI_PDK_SOURCE'),'packages',d.getVar('TI_PDK_COMP_PATH'))
|
|
s = d.getVar('S')
|
|
|
|
# Set up the directory structure, except for the root of the sources
|
|
# hard-linked.
|
|
bb.utils.mkdirhier(s)
|
|
os.rmdir(s)
|
|
|
|
# Recursively hard-link the sources
|
|
shutil.copytree(src, s, copy_function=os.link)
|
|
}
|
|
|
|
# Make sure that ti-pdk-source is unpacked before we set up the hardlinks.
|
|
python __anonymous () {
|
|
pn = d.getVar('PN')
|
|
pdk_src_pn = d.getVar('TI_PDK_SOURCE_PN')
|
|
if pn != pdk_src_pn:
|
|
d.appendVarFlag('do_unpack', 'depends', ' ${TI_PDK_SOURCE_PN}:do_unpack')
|
|
}
|