mirror of
https://git.yoctoproject.org/poky
synced 2026-07-16 15:57:04 +00:00
Trevor Woerner
d376e31c92
This patch fixes a build warning which is promoted to an error via -Werror. changes from v1: * put "Upstream-Status" in patch itself, not in OE patch header * fix commit wording (From OE-Core rev: 4b41f4199d77144a629897173cff3d1efcfa85f9) (From OE-Core rev: 69f9022126d3cd21001f48ec36730982e53a6a48) Signed-off-by: Trevor Woerner <trevor.woerner@linaro.org> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
68 lines
2.0 KiB
BlitzBasic
68 lines
2.0 KiB
BlitzBasic
SUMMARY = "GRUB2 is the next-generation GRand Unified Bootloader"
|
|
|
|
DESCRIPTION = "GRUB2 is the next generaion of a GPLed bootloader \
|
|
intended to unify bootloading across x86 operating systems. In \
|
|
addition to loading the Linux kernel, it implements the Multiboot \
|
|
standard, which allows for flexible loading of multiple boot images."
|
|
|
|
HOMEPAGE = "http://www.gnu.org/software/grub/"
|
|
SECTION = "bootloaders"
|
|
|
|
LICENSE = "GPLv3"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
|
|
|
|
DEPENDS = "autogen-native flex-native bison-native xz freetype"
|
|
|
|
DEFAULT_PREFERENCE = "-1"
|
|
DEFAULT_PREFERENCE_arm = "1"
|
|
|
|
PV = "2.00+${SRCPV}"
|
|
SRCREV = "0776112c5311196889a15058a3b1be4c81ba5e05"
|
|
SRC_URI = "git://git.savannah.gnu.org/grub.git \
|
|
file://40_custom \
|
|
file://autogen.sh-exclude-pc.patch \
|
|
file://grub-2.00-add-oe-kernel.patch \
|
|
file://asciih-fix-build-warning-error.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
COMPATIBLE_HOST = '(x86_64.*|i.86.*|arm.*|aarch64.*)-(linux.*|freebsd.*)'
|
|
|
|
inherit autotools
|
|
inherit gettext
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[grub-mount] = "--enable-grub-mount,--disable-grub-mount,fuse"
|
|
PACKAGECONFIG[device-mapper] = "--enable-device-mapper,--disable-device-mapper,lvm2"
|
|
|
|
# configure.ac has code to set this automagically from the target tuple
|
|
# but the OE freeform one (core2-foo-bar-linux) don't work with that.
|
|
|
|
GRUBPLATFORM_arm = "uboot"
|
|
GRUBPLATFORM_aarch64 = "efi"
|
|
GRUBPLATFORM ??= "pc"
|
|
|
|
EXTRA_OECONF = "--with-platform=${GRUBPLATFORM} --disable-grub-mkfont --program-prefix="" \
|
|
--enable-liblzma=no --enable-device-mapper=no --enable-libzfs=no"
|
|
|
|
do_configure_prepend() {
|
|
( cd ${S}
|
|
${S}/autogen.sh )
|
|
}
|
|
|
|
do_install_append () {
|
|
install -d ${D}${sysconfdir}/grub.d
|
|
install -m 0755 ${WORKDIR}/40_custom ${D}${sysconfdir}/grub.d/40_custom
|
|
|
|
}
|
|
|
|
# debugedit chokes on bare metal binaries
|
|
INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
|
|
|
|
RDEPENDS_${PN} = "diffutils freetype"
|
|
FILES_${PN}-dbg += "${libdir}/${BPN}/*/.debug"
|
|
|
|
INSANE_SKIP_${PN} = "arch"
|
|
INSANE_SKIP_${PN}-dbg = "arch"
|