mirror of
https://git.yoctoproject.org/poky
synced 2026-07-17 04:07:06 +00:00
Richard Purdie
287c3bec51
attr needs libintl headers and libs. Add in the missing dependency and ensure the linker flag gets passed in multilib builds by replacing the PN == BPN check with a class-target override instead. (From OE-Core rev: c19fb913006eb53025e5db1574d973c8d7ceec76) (From OE-Core rev: 240d25d0fbcbedbdea82a7a103e672e2aad74ba8) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
38 lines
1.2 KiB
PHP
38 lines
1.2 KiB
PHP
SUMMARY = "Utilities for manipulating filesystem extended attributes"
|
|
HOMEPAGE = "http://savannah.nongnu.org/projects/attr/"
|
|
SECTION = "libs"
|
|
|
|
DEPENDS = "ncurses virtual/libintl"
|
|
|
|
LICENSE = "LGPLv2.1+ & GPLv2+"
|
|
LICENSE_${PN} = "GPLv2+"
|
|
LICENSE_lib${BPN} = "LGPLv2.1+"
|
|
LIC_FILES_CHKSUM = "file://doc/COPYING;md5=2d0aa14b3fce4694e4f615e30186335f \
|
|
file://attr/attr.c;endline=17;md5=be0403261f0847e5f43ed5b08d19593c \
|
|
file://libattr/libattr.c;endline=17;md5=7970f77049f8fa1199fff62a7ab724fb"
|
|
|
|
SRC_URI = "http://download.savannah.gnu.org/releases/attr/${BP}.src.tar.gz \
|
|
file://run-ptest \
|
|
"
|
|
|
|
require ea-acl.inc
|
|
|
|
# libdir should point to .la
|
|
do_install_append() {
|
|
sed -i ${D}${libdir}/libattr.la -e \
|
|
s,^libdir=\'${base_libdir}\'$,libdir=\'${libdir}\',
|
|
}
|
|
|
|
inherit ptest
|
|
|
|
do_install_ptest() {
|
|
tar -cf - test/ --exclude ext | ( cd ${D}${PTEST_PATH} && tar -xf - )
|
|
mkdir ${D}${PTEST_PATH}/include
|
|
for i in builddefs buildmacros buildrules; \
|
|
do cp ${S}/include/$i ${D}${PTEST_PATH}/include/; \
|
|
done
|
|
sed -e 's|; @echo|; echo|' -i ${D}${PTEST_PATH}/test/Makefile
|
|
}
|
|
|
|
RDEPENDS_${PN}-ptest = "coreutils perl-module-filehandle perl-module-getopt-std perl-module-posix"
|