mirror of
https://git.yoctoproject.org/poky
synced 2026-07-27 19:37:10 +00:00
Richard Purdie
3476a49b10
This adds a binconfig-disabled class which can be used by recipes where a -config file is installed but we wish to disable it and just rely on the .pc files instead. Rather than simply deleting it, we make the script "exit 1" so that it can be found in PATH and raise a build error rather than something silently falling back to the build system for example. Rather than randomly finding -config files, this adds in the specification of a list of binconfig scripts which is more deterministic and maintainable moving forward. This patch converts various users in OE-Core to use this, a world build of OE-Core tests out ok with this change. There will likely be issues in other layers however, hence this being a RFT. (From OE-Core rev: 5870bd272b0b077d0826fb900b251884c1c05061) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
76 lines
2.6 KiB
BlitzBasic
76 lines
2.6 KiB
BlitzBasic
DESCRIPTION = "The PCRE library is a set of functions that implement regular \
|
|
expression pattern matching using the same syntax and semantics as Perl 5. PCRE \
|
|
has its own native API, as well as a set of wrapper functions that correspond \
|
|
to the POSIX regular expression API."
|
|
SUMMARY = "Perl Compatible Regular Expressions"
|
|
HOMEPAGE = "http://www.pcre.org"
|
|
SECTION = "devel"
|
|
LICENSE = "BSD"
|
|
LIC_FILES_CHKSUM = "file://LICENCE;md5=ded617e975f28e15952dc68b84a7ac1a"
|
|
SRC_URI = "${SOURCEFORGE_MIRROR}/project/pcre/pcre/${PV}/pcre-${PV}.tar.bz2 \
|
|
file://pcre-cross.patch \
|
|
file://fix-pcre-name-collision.patch \
|
|
file://run-ptest \
|
|
file://Makefile \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "6aacb23986adccd9b3bc626c00979958"
|
|
SRC_URI[sha256sum] = "a961c1c78befef263cc130756eeca7b674b4e73a81533293df44e4265236865b"
|
|
|
|
S = "${WORKDIR}/pcre-${PV}"
|
|
|
|
PROVIDES += "pcre"
|
|
DEPENDS += "bzip2 zlib"
|
|
|
|
PACKAGECONFIG[pcretest-readline] = "--enable-pcretest-libreadline,--disable-pcretest-libreadline,readline,"
|
|
|
|
BINCONFIG = "${bindir}/pcre-config"
|
|
|
|
inherit autotools binconfig-disabled ptest
|
|
|
|
PARALLEL_MAKE = ""
|
|
|
|
EXTRA_OECONF = "\
|
|
--enable-newline-is-lf \
|
|
--enable-rebuild-chartables \
|
|
--enable-utf8 \
|
|
--with-link-size=2 \
|
|
--with-match-limit=10000000 \
|
|
"
|
|
|
|
# Set LINK_SIZE in BUILD_CFLAGS given that the autotools bbclass use it to
|
|
# set CFLAGS_FOR_BUILD, required for the libpcre build.
|
|
BUILD_CFLAGS =+ "-DLINK_SIZE=2 -I${B}"
|
|
CFLAGS += "-D_REENTRANT"
|
|
CXXFLAGS_append_powerpc = " -lstdc++"
|
|
|
|
PACKAGES =+ "libpcrecpp libpcreposix pcregrep pcregrep-doc pcretest pcretest-doc"
|
|
|
|
SUMMARY_libpcrecpp = "${SUMMARY} - C++ wrapper functions"
|
|
SUMMARY_libpcreposix = "${SUMMARY} - C wrapper functions based on the POSIX regex API"
|
|
SUMMARY_pcregrep = "grep utility that uses perl 5 compatible regexes"
|
|
SUMMARY_pcregrep-doc = "grep utility that uses perl 5 compatible regexes - docs"
|
|
SUMMARY_pcretest = "program for testing Perl-comatible regular expressions"
|
|
SUMMARY_pcretest-doc = "program for testing Perl-comatible regular expressions - docs"
|
|
|
|
FILES_libpcrecpp = "${libdir}/libpcrecpp.so.*"
|
|
FILES_libpcreposix = "${libdir}/libpcreposix.so.*"
|
|
FILES_pcregrep = "${bindir}/pcregrep"
|
|
FILES_pcregrep-doc = "${mandir}/man1/pcregrep.1"
|
|
FILES_pcretest = "${bindir}/pcretest"
|
|
FILES_pcretest-doc = "${mandir}/man1/pcretest.1"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
do_install_ptest() {
|
|
t=${D}${PTEST_PATH}
|
|
cp ${WORKDIR}/Makefile $t
|
|
cp -r ${S}/testdata $t
|
|
for i in pcre_stringpiece_unittest pcregrep pcretest; \
|
|
do cp ${B}/.libs/$i $t; \
|
|
done
|
|
for i in RunTest RunGrepTest test-driver; \
|
|
do cp ${S}/$i $t; \
|
|
done
|
|
}
|